UFES PPGCosmo thesis and dissertation (PPGCosmoThesis)

%% This BibTeX bibliography file was created using BibDesk.
%% http://bibdesk.sourceforge.net/


%% Created for Davi Rodrigues at 2020-09-02 00:51:16 -0300 


%% Saved with string encoding Unicode (UTF-8) 



@article{Ade:2015xua,
	Archiveprefix = {arXiv},
	Author = {Ade, P. A. R. and others},
	Collaboration = {Planck},
	Date-Added = {2017-04-10 02:28:40 +0000},
	Date-Modified = {2017-04-10 02:28:40 +0000},
	Doi = {10.1051/0004-6361/201525830},
	Eprint = {1502.01589},
	Journal = {Astron. Astrophys.},
	Pages = {A13},
	Primaryclass = {astro-ph.CO},
	Slaccitation = {%%CITATION = ARXIV:1502.01589;%%},
	Title = {{Planck 2015 results. XIII. Cosmological parameters}},
	Volume = {594},
	Year = {2016},
	Bdsk-Url-1 = {http://dx.doi.org/10.1051/0004-6361/201525830}}

@article{Arnowitt:1962hi,
	Archiveprefix = {arXiv},
	Author = {Arnowitt, Richard L. and Deser, Stanley and Misner, Charles W.},
	Date-Added = {2016-07-23 13:58:02 +0000},
	Date-Modified = {2016-07-23 13:58:02 +0000},
	Doi = {10.1007/s10714-008-0661-1},
	Eprint = {gr-qc/0405109},
	Journal = {Gen. Rel. Grav.},
	Pages = {1997-2027},
	Primaryclass = {gr-qc},
	Slaccitation = {%%CITATION = GR-QC/0405109;%%},
	Title = {{The Dynamics of general relativity}},
	Volume = {40},
	Year = {2008},
	Bdsk-Url-1 = {http://dx.doi.org/10.1007/s10714-008-0661-1}}

@article{Abbott:2016blz,
	Archiveprefix = {arXiv},
	Author = {Abbott, B. P. and others},
	Collaboration = {Virgo, LIGO Scientific},
	Date-Added = {2016-02-25 03:34:55 +0000},
	Date-Modified = {2016-02-25 03:34:55 +0000},
	Doi = {10.1103/PhysRevLett.116.061102},
	Eprint = {1602.03837},
	Journal = {Phys. Rev. Lett.},
	Number = {6},
	Pages = {061102},
	Primaryclass = {gr-qc},
	Reportnumber = {LIGO-P150914},
	Slaccitation = {%%CITATION = ARXIV:1602.03837;%%},
	Title = {{Observation of Gravitational Waves from a Binary Black Hole Merger}},
	Volume = {116},
	Year = {2016},
	Bdsk-Url-1 = {http://dx.doi.org/10.1103/PhysRevLett.116.061102}}

@article{Akerib:2013tjd,
	Archiveprefix = {arXiv},
	Author = {Akerib, D.S. and others},
	Collaboration = {LUX},
	Date-Added = {2014-07-24 20:18:49 +0000},
	Date-Modified = {2018-01-18 03:22:40 +0000},
	Doi = {10.1103/PhysRevLett.112.091303},
	Eprint = {1310.8214},
	Journal = {Phys. Rev. Lett.},
	Pages = {091303},
	Primaryclass = {astro-ph.CO},
	Slaccitation = {%%CITATION = ARXIV:1310.8214;%%},
	Title = {{First results from the LUX dark matter experiment at the Sanford Underground Research Facility}},
	Volume = {112},
	Year = {2014},
	Bdsk-Url-1 = {http://dx.doi.org/10.1103/PhysRevLett.112.091303}}

@book{0521857937,
	Author = {Mo, Houjun and van den Bosch, Frank and White, Simon},
	Date-Added = {2012-02-23 20:44:39 -0200},
	Date-Modified = {2012-11-28 04:16:48 +0000},
	Isbn = {0521857937},
	Publisher = {Cambridge University Press},
	Title = {{Galaxy Formation and Evolution}},
	Year = {2010},
	Bdsk-Url-1 = {http://www.amazon.com/Galaxy-Formation-Evolution-Houjun-Mo/dp/0521857937%3FSubscriptionId%3D0JYN1NVW651KCA56C102%26tag%3Dtechkie-20%26linkCode%3Dxm2%26camp%3D2025%26creative%3D165953%26creativeASIN%3D0521857937},
	Bdsk-Url-2 = {http://www.amazon.com/Galaxy-Formation-Evolution-Houjun-Mo/dp/0521857937%3FSubscriptionId%3D0JYN1NVW651KCA56C102%26tag%3Dtechkie-20%26linkCode%3Dxm2%26camp%3D2025%26creative%3D165953%26creativeASIN%3D0521857937}}

%%%% PPGCosmoN.bst
%%%% This bst file should be used with PPGCosmoThesis.cls
%%%% This variation is based on the unsrturl.bst style
%%%% (http://tug.ctan.org/tex-archive/biblio/bibtex/contrib/urlbst/unsrturl.bst)
%%%% By Davi C. Rodrigues. August / 2020.
%
% List of changes:
% The first names of authors are always abbreviated.
% Macros on month names and computational journals were removed.
% For articles:
%   Link on the name of the journal (using the doi url) was inserted. It uses the color "journalcolor", defined in PPGCosmoThesis.cls,
%   removed pubmed support.
%   journal volume is in boldface,
%   title is in italics,
%   only the article first page number is shown, instead of first and last,
%   the comma between itens was replaced by space,
%   year appears between parenthesis,
%   the doi is not printed (it is in the link).
%
% Comment: The color for the arxiv link follows the urlcolor defined by hyperref or \hypersetup.
% Comment: Each edited line, or added function, contains a comment with "PPGCosmoN"


% THE ORIGINAL METADATA FROM unsrturl.bst:
%
%%% Modification of BibTeX style file /usr/local/texlive/2019/texmf-dist/bibtex/bst/base/unsrt.bst
%%% ... by urlbst, version 0.8 (marked with "% urlbst")
%%% See <http://purl.org/nxg/dist/urlbst>
%%% Modifications Copyright 2002-03, 2005-12, 2014, 2019, Norman Gray,
%%% and distributed under the terms of the LPPL; see README for discussion.
%%%
%%% Added webpage entry type, and url and lastchecked fields.
%%% Added eprint support.
%%% Added DOI support.
%%% Added PUBMED support.
%%% Added hyperref support.
%%% Original headers follow...

% BibTeX standard bibliography style `unsrt'
   % Version 0.99b (8-Dec-10 release) for BibTeX versions 0.99a or later.
   % Copyright (C) 1984, 1985, 1988, 2010 Howard Trickey and Oren Patashnik.
   % Unlimited copying and redistribution of this file are permitted as long as
   % it is unmodified.  Modifications (and redistribution of modified versions)
   % are also permitted, but only if the resulting file is renamed to something
   % besides btxbst.doc, plain.bst, unsrt.bst, alpha.bst, and abbrv.bst.
   % This restriction helps ensure that all standard styles are identical.
   % The file btxbst.doc has the documentation for this style.

ENTRY
  { address
    author
    booktitle
    chapter
    edition
    editor
    howpublished
    institution
    journal
    key
    month
    note
    number
    organization
    pages
    publisher
    school
    series
    title
    type
    volume
    year
    eprint % urlbst
    doi % urlbst
    pubmed % urlbst
    url % urlbst
    lastchecked % urlbst
  }
  {}
  { label }

INTEGERS { output.state before.all mid.sentence after.sentence after.block }

% urlbst...
% urlbst constants and state variables
STRINGS { urlintro
  eprinturl eprintprefix doiprefix doiurl pubmedprefix pubmedurl
  citedstring onlinestring linktextstring
  openinlinelink closeinlinelink }
INTEGERS { hrefform inlinelinks makeinlinelink
  addeprints adddoiresolver addpubmedresolver isyear }   %PPGCosmoN: declares new variable: isyear
FUNCTION {init.urlbst.variables}
{
  % The following constants may be adjusted by hand, if desired

  % The first set allow you to enable or disable certain functionality.
  #1 'addeprints :=         % 0=no eprints; 1=include eprints
  #0 'adddoiresolver :=     % 0=no DOI resolver; 1=include it                      %PPGCosmoN: changed from 1 to 0.
  #0 'addpubmedresolver :=     % 0=no PUBMED resolver; 1=include it                % PPGCosmoN: changed from 1 to 0.
  #2 'hrefform :=           % 0=no crossrefs; 1=hypertex xrefs; 2=hyperref refs
  #0 'inlinelinks :=        % 0=URLs explicit; 1=URLs attached to titles

  % String constants, which you _might_ want to tweak.
  "URL: " 'urlintro := % prefix before URL; typically "Available from:" or "URL":
  "online" 'onlinestring := % indication that resource is online; typically "online"
  "cited " 'citedstring := % indicator of citation date; typically "cited "
  "[link]" 'linktextstring := % dummy link text; typically "[link]"
  "http://arxiv.org/abs/" 'eprinturl := % prefix to make URL from eprint ref
  "arXiv:" 'eprintprefix := % text prefix printed before eprint ref; typically "arXiv:"
  "https://doi.org/" 'doiurl := % prefix to make URL from DOI
  "doi:" 'doiprefix :=      % text prefix printed before DOI ref; typically "doi:"
  "http://www.ncbi.nlm.nih.gov/pubmed/" 'pubmedurl := % prefix to make URL from PUBMED
  "PMID:" 'pubmedprefix :=      % text prefix printed before PUBMED ref; typically "PMID:"

  % The following are internal state variables, not configuration constants,
  % so they shouldn't be fiddled with.
  #0 'makeinlinelink :=     % state variable managed by possibly.setup.inlinelink
  "" 'openinlinelink :=     % ditto
  "" 'closeinlinelink :=    % ditto
  #0 'isyear :=             %PPGCosmoN: new test variable. Used to insert the year parenthesis.
}
INTEGERS {
  bracket.state
  outside.brackets
  open.brackets
  within.brackets
  close.brackets
}
% ...urlbst to here
FUNCTION {init.state.consts}
{ #0 'outside.brackets := % urlbst...
  #1 'open.brackets :=
  #2 'within.brackets :=
  #3 'close.brackets := % ...urlbst to here

  #0 'before.all :=
  #1 'mid.sentence :=
  #2 'after.sentence :=
  #3 'after.block :=
}

STRINGS { s t }

% urlbst

FUNCTION {output.nonnull.original}
{ 's :=
  output.state mid.sentence =
    { #1 isyear =                        %PPGCosmoN: introduced this if$, the original was { ", " * write$ }
       { " (" * write$ }
       { " " * write$ }
     if$
    }
    { output.state after.block =
        { add.period$ write$
          newline$
          "\newblock " write$
        }
        { output.state before.all =
            'write$
            { add.period$ " " * write$ }
          if$
        }
      if$
      mid.sentence 'output.state :=
    }
  if$
  s
}

% urlbst...
% The following three functions are for handling inlinelink.  They wrap
% a block of text which is potentially output with write$ by multiple
% other functions, so we don't know the content a priori.
% They communicate between each other using the variables makeinlinelink
% (which is true if a link should be made), and closeinlinelink (which holds
% the string which should close any current link.  They can be called
% at any time, but start.inlinelink will be a no-op unless something has
% previously set makeinlinelink true, and the two ...end.inlinelink functions
% will only do their stuff if start.inlinelink has previously set
% closeinlinelink to be non-empty.
% (thanks to 'ijvm' for suggested code here)
FUNCTION {uand}
{ 'skip$ { pop$ #0 } if$ } % 'and' (which isn't defined at this point in the file)
FUNCTION {possibly.setup.inlinelink}
{ makeinlinelink hrefform #0 > uand
    { doi empty$ adddoiresolver uand
        { pubmed empty$ addpubmedresolver uand
            { eprint empty$ addeprints uand
                { url empty$
                    { "" }
                    { url }
                  if$ }
                { eprinturl eprint * }
              if$ }
            { pubmedurl pubmed * }
          if$ }
        { doiurl doi * }
      if$
      % an appropriately-formatted URL is now on the stack
      hrefform #1 = % hypertex
        { "\special {html:<a href=" quote$ * swap$ * quote$ * "> }{" * 'openinlinelink :=
          "\special {html:</a>}" 'closeinlinelink := }
        { "{\hypersetup{urlcolor=journalcolor}\href{" swap$ * "} {" * 'openinlinelink := % hrefform=#2 -- hyperref  %PPGCosmoN: inserted the hypersetup.
          % the space between "} {" matters: a URL of just the right length can cause "\% newline em"
          "}}" 'closeinlinelink := }                                                                              %PPGCosmoN: put a second } to close hypersetup.
      if$
      #0 'makeinlinelink :=
      }
    'skip$
  if$ % makeinlinelink
}
FUNCTION {add.inlinelink}
{ openinlinelink empty$
    'skip$
    { openinlinelink swap$ * closeinlinelink *
      "" 'openinlinelink :=
      }
  if$
}
FUNCTION {output.nonnull}
{ % Save the thing we've been asked to output
  's :=
  % If the bracket-state is close.brackets, then add a close-bracket to
  % what is currently at the top of the stack, and set bracket.state
  % to outside.brackets
  bracket.state close.brackets =
    { "]" *
      outside.brackets 'bracket.state :=
    }
    'skip$
  if$
  bracket.state outside.brackets =
    { % We're outside all brackets -- this is the normal situation.
      % Write out what's currently at the top of the stack, using the
      % original output.nonnull function.
      s
      add.inlinelink
      output.nonnull.original % invoke the original output.nonnull
    }
    { % Still in brackets.  Add open-bracket or (continuation) comma, add the
      % new text (in s) to the top of the stack, and move to the close-brackets
      % state, ready for next time (unless inbrackets resets it).  If we come
      % into this branch, then output.state is carefully undisturbed.
      bracket.state open.brackets =
        { " [" * }
        { ", " * } % bracket.state will be within.brackets
      if$
      s *
      close.brackets 'bracket.state :=
    }
  if$
}

% Call this function just before adding something which should be presented in
% brackets.  bracket.state is handled specially within output.nonnull.
FUNCTION {inbrackets}
{ bracket.state close.brackets =
    { within.brackets 'bracket.state := } % reset the state: not open nor closed
    { open.brackets 'bracket.state := }
  if$
}

FUNCTION {format.lastchecked}
{ lastchecked empty$
    { "" }
    { inbrackets citedstring lastchecked * }
  if$
}
% ...urlbst to here

FUNCTION {output}
{ duplicate$ empty$
    'pop$
    'output.nonnull
  if$
}

FUNCTION {output.check}
{ 't :=
  duplicate$ empty$
    { pop$ "empty " t * " in " * cite$ * warning$ }
    'output.nonnull
  if$
}

FUNCTION {output.bibitem.original} % urlbst (renamed from output.bibitem, so it can be wrapped below)
{ newline$
  "\bibitem{" write$
  cite$ write$
  "}" write$
  newline$
  ""
  before.all 'output.state :=
}

FUNCTION {fin.entry.original} % urlbst (renamed from fin.entry, so it can be wrapped below)
{ add.period$
  write$
  newline$
}

FUNCTION {new.block}
{ output.state before.all =
    'skip$
    { after.block 'output.state := }
  if$
}

FUNCTION {new.sentence}
{ output.state after.block =
    'skip$
    { output.state before.all =
        'skip$
        { after.sentence 'output.state := }
      if$
    }
  if$
}

FUNCTION {not}
{   { #0 }
    { #1 }
  if$
}

FUNCTION {and}
{   'skip$
    { pop$ #0 }
  if$
}

FUNCTION {or}
{   { pop$ #1 }
    'skip$
  if$
}

FUNCTION {new.block.checka}
{ empty$
    'skip$
    'new.block
  if$
}

FUNCTION {new.block.checkb}
{ empty$
  swap$ empty$
  and
    'skip$
    'new.block
  if$
}

FUNCTION {new.sentence.checka}
{ empty$
    'skip$
    'new.sentence
  if$
}

FUNCTION {new.sentence.checkb}
{ empty$
  swap$ empty$
  and
    'skip$
    'new.sentence
  if$
}

FUNCTION {field.or.null}
{ duplicate$ empty$
    { pop$ "" }
    'skip$
  if$
}

FUNCTION {boldface}                     % PPGCosmoN: added function.
{ duplicate$ empty$
    { pop$ "" }
    { "{\bfseries " swap$ * "}" * }
  if$
}


FUNCTION {emphasize}
{ duplicate$ empty$
    { pop$ "" }
    { "{\em " swap$ * "}" * }
  if$
}

INTEGERS { nameptr namesleft numnames }


FUNCTION {format.names}
{ 's :=
  #1 'nameptr :=
  s num.names$ 'numnames :=
  numnames 'namesleft :=
    { namesleft #0 > }
    { s nameptr "{f. }{vv }{ll}{,jj}" format.name$ 't :=   %PPGCosmoN: first name is abbreviated.
      nameptr #1 >
        { namesleft #1 >
            { ", " * t * }
            { numnames #2 >
                { "," * }
                'skip$
              if$
              t "others" =
                { " et~al." * }
                { " and " * t * }
              if$
            }
          if$
        }
        't
      if$
      nameptr #1 + 'nameptr :=
      namesleft #1 - 'namesleft :=
    }
  while$
}

FUNCTION {format.authors}
{ author empty$
    { "" }
    { author format.names }
  if$
}

FUNCTION {format.editors}
{ editor empty$
    { "" }
    { editor format.names
      editor num.names$ #1 >
        { ", editors" * }
        { ", editor" * }
      if$
    }
  if$
}

FUNCTION {format.title}
{ title empty$
    { "" }
    { title emphasize "t" change.case$ }
  if$
}

FUNCTION {n.dashify}
{ 't :=
  ""
    { t empty$ not }
    { t #1 #1 substring$ "-" =
        { t #1 #2 substring$ "--" = not
            { "--" *
              t #2 global.max$ substring$ 't :=
            }
            {   { t #1 #1 substring$ "-" = }
                { "-" *
                  t #2 global.max$ substring$ 't :=
                }
              while$
            }
          if$
        }
        { t #1 #1 substring$ *
          t #2 global.max$ substring$ 't :=
        }
      if$
    }
  while$
}

FUNCTION {format.date}
{ year empty$
    { month empty$
        { "" }
        { "there's a month but no year in " cite$ * warning$
          month
        }
      if$
    }
    { month empty$
        'year
        'year                                %PPGCosmoN: was { month " " * year * }. We do not want to show the month ever.
      if$
    }
  if$
}

FUNCTION {format.btitle}
{ title emphasize
}

FUNCTION {tie.or.space.connect}
{ duplicate$ text.length$ #3 <
    { "~" }
    { " " }
  if$
  swap$ * *
}

FUNCTION {either.or.check}
{ empty$
    'pop$
    { "can't use both " swap$ * " fields in " * cite$ * warning$ }
  if$
}

FUNCTION {format.bvolume}
{ volume empty$
    { "" }
    { "volume" volume tie.or.space.connect
      series empty$
        'skip$
        { " of " * series emphasize * }
      if$
      "volume and number" number either.or.check
    }
  if$
}

FUNCTION {format.number.series}
{ volume empty$
    { number empty$
        { series field.or.null }
        { output.state mid.sentence =
            { "number" }
            { "Number" }
          if$
          number tie.or.space.connect
          series empty$
            { "there's a number but no series in " cite$ * warning$ }
            { " in " * series * }
          if$
        }
      if$
    }
    { "" }
  if$
}

FUNCTION {format.edition}
{ edition empty$
    { "" }
    { output.state mid.sentence =
        { edition "l" change.case$ " edition" * }
        { edition "t" change.case$ " edition" * }
      if$
    }
  if$
}

INTEGERS { multiresult }

FUNCTION {multi.page.check}
{ 't :=
  #0 'multiresult :=
    { multiresult not
      t empty$ not
      and
    }
    { t #1 #1 substring$
      duplicate$ "-" =
      swap$ duplicate$ "," =
      swap$ "+" =
      or or
        { #1 'multiresult := }
        { t #2 global.max$ substring$ 't := }
      if$
    }
  while$
  multiresult
}

FUNCTION {format.pages}
{ pages empty$
    { "" }
    { pages multi.page.check
        { "pages" pages n.dashify tie.or.space.connect }
        { "page" pages tie.or.space.connect }
      if$
    }
  if$
}

FUNCTION {format.vol.num.pages}
{ volume field.or.null
  number empty$
    'skip$
    { "(" number * ")" * *
      volume empty$
        { "there's a number but no volume in " cite$ * warning$ }
        'skip$
      if$
    }
  if$
  pages empty$
    'skip$
    { duplicate$ empty$
        { pop$ format.pages }
        { ":" * pages n.dashify * }
      if$
    }
  if$
}

FUNCTION {first.page.number}                       %PPGCosmoN: added function
{ 't :=
  ""
    { t "" =
        { #0 }
        { t #1 #1 substring$ "-" = not }
      if$
    }
    { t #1 #1 substring$ *
      t #2 global.max$ substring$ 't :=
    }
  while$
}


FUNCTION {format.vol.page}                         %PPGCosmoN: added function
{ volume boldface field.or.null                    %PPGCosmoN: Uses volume in boldface
  pages empty$
    'skip$
    { duplicate$ empty$
        { pop$ format.pages }
        { " " * pages first.page.number * }       %PPGCosmoN: no coma after the volume.
      if$
    }
  if$
}


FUNCTION {format.chapter.pages}
{ chapter empty$
    'format.pages
    { type empty$
        { "chapter" }
        { type "l" change.case$ }
      if$
      chapter tie.or.space.connect
      pages empty$
        'skip$
        { ", " * format.pages * }
      if$
    }
  if$
}

FUNCTION {format.in.ed.booktitle}
{ booktitle empty$
    { "" }
    { editor empty$
        { "In " booktitle emphasize * }
        { "In " format.editors * ", " * booktitle emphasize * }
      if$
    }
  if$
}

FUNCTION {empty.misc.check}
{ author empty$ title empty$ howpublished empty$
  month empty$ year empty$ note empty$
  and and and and and
    { "all relevant fields are empty in " cite$ * warning$ }
    'skip$
  if$
}

FUNCTION {format.thesis.type}
{ type empty$
    'skip$
    { pop$
      type "t" change.case$
    }
  if$
}

FUNCTION {format.tr.number}
{ type empty$
    { "Technical Report" }
    'type
  if$
  number empty$
    { "t" change.case$ }
    { number tie.or.space.connect }
  if$
}

FUNCTION {format.article.crossref}
{ key empty$
    { journal empty$
        { "need key or journal for " cite$ * " to crossref " * crossref *
          warning$
          ""
        }
        { "In {\em " journal * "\/}" * }
      if$
    }
    { "In " key * }
  if$
  " \cite{" * crossref * "}" *
}

FUNCTION {format.crossref.editor}
{ editor #1 "{vv~}{ll}" format.name$
  editor num.names$ duplicate$
  #2 >
    { pop$ " et~al." * }
    { #2 <
        'skip$
        { editor #2 "{f. }{vv }{ll}{ jj}" format.name$ "others" =   % PPGCosmoN: abbreviated first name.
            { " et~al." * }
            { " and " * editor #2 "{vv~}{ll}" format.name$ * }
          if$
        }
      if$
    }
  if$
}

FUNCTION {format.book.crossref}
{ volume empty$
    { "empty volume in " cite$ * "'s crossref of " * crossref * warning$
      "In "
    }
    { "Volume" volume tie.or.space.connect
      " of " *
    }
  if$
  editor empty$
  editor field.or.null author field.or.null =
  or
    { key empty$
        { series empty$
            { "need editor, key, or series for " cite$ * " to crossref " *
              crossref * warning$
              "" *
            }
            { "{\em " * series * "\/}" * }
          if$
        }
        { key * }
      if$
    }
    { format.crossref.editor * }
  if$
  " \cite{" * crossref * "}" *
}

FUNCTION {format.incoll.inproc.crossref}
{ editor empty$
  editor field.or.null author field.or.null =
  or
    { key empty$
        { booktitle empty$
            { "need editor, key, or booktitle for " cite$ * " to crossref " *
              crossref * warning$
              ""
            }
            { "In {\em " booktitle * "\/}" * }
          if$
        }
        { "In " key * }
      if$
    }
    { "In " format.crossref.editor * }
  if$
  " \cite{" * crossref * "}" *
}

% urlbst...
% Functions for making hypertext links.
% In all cases, the stack has (link-text href-url)
%
% make 'null' specials
FUNCTION {make.href.null}
{
  pop$
}
% make hypertex specials
FUNCTION {make.href.hypertex}
{
  "\special {html:<a href=" quote$ *
  swap$ * quote$ * "> }" * swap$ *
  "\special {html:</a>}" *
}

% make hyperref specials
FUNCTION {make.href.hyperref}
{
    "\href {" swap$ * "} {\path{" * swap$ * "}}" *
}

FUNCTION {make.href}
{ hrefform #2 =
    'make.href.hyperref      % hrefform = 2
    { hrefform #1 =
        'make.href.hypertex  % hrefform = 1
        'make.href.null      % hrefform = 0 (or anything else)
      if$
    }
  if$
}

% If inlinelinks is true, then format.url should be a no-op, since it's
% (a) redundant, and (b) could end up as a link-within-a-link.
FUNCTION {format.url}
{ inlinelinks #1 = url empty$ or
   { "" }
   { hrefform #1 =
       { % special case -- add HyperTeX specials
         urlintro "\url{" url * "}" * url make.href.hypertex * }
       { urlintro "\url{" * url * "}" * }
     if$
   }
  if$
}
FUNCTION {format.eprint}
{ eprint empty$
    { "" }
    { eprintprefix eprint * eprinturl eprint * make.href }
  if$
}

FUNCTION {format.doi}
{ doi empty$
    { "" }
    { doiprefix doi * doiurl doi * make.href }
  if$
}

FUNCTION {format.pubmed}
{ pubmed empty$
    { "" }
    { pubmedprefix pubmed * pubmedurl pubmed * make.href }
  if$
}

% Output a URL.  We can't use the more normal idiom (something like
% `format.url output'), because the `inbrackets' within
% format.lastchecked applies to everything between calls to `output',
% so that `format.url format.lastchecked * output' ends up with both
% the URL and the lastchecked in brackets.
FUNCTION {output.url}
{ url empty$
    'skip$
    { new.block
      format.url output
      format.lastchecked output
    }
  if$
}

FUNCTION {output.web.refs}
{
  new.block
  inlinelinks
    'skip$ % links were inline -- don't repeat them
    { % If the generated DOI will be the same as the URL,
      % then don't print the URL (thanks to Joseph Wright for this code,
      % at http://tex.stackexchange.com/questions/5660)
      adddoiresolver
          doiurl doi empty$ { "X" } { doi } if$ * % DOI URL to be generated
          url empty$ { "Y" } { url } if$          % the URL, or "Y" if empty
          =                                       % are the strings equal?
          and
        'skip$
        { output.url }
      if$
      addeprints eprint empty$ not and
        { format.eprint output.nonnull }
        'skip$
      if$
      adddoiresolver doi empty$ not and
        { format.doi output.nonnull }
        'skip$
      if$
      addpubmedresolver pubmed empty$ not and
        { format.pubmed output.nonnull }
        'skip$
      if$
    }
  if$
}

% Wrapper for output.bibitem.original.
% If the URL field is not empty, set makeinlinelink to be true,
% so that an inline link will be started at the next opportunity
FUNCTION {output.bibitem}
{ outside.brackets 'bracket.state :=
  output.bibitem.original
  inlinelinks url empty$ not doi empty$ not or pubmed empty$ not or eprint empty$ not or and
    { #1 'makeinlinelink := }
    { #0 'makeinlinelink := }
  if$
}

% Wrapper for fin.entry.original
FUNCTION {fin.entry}
{ output.web.refs  % urlbst
  makeinlinelink       % ooops, it appears we didn't have a title for inlinelink
    { possibly.setup.inlinelink % add some artificial link text here, as a fallback
      linktextstring output.nonnull }
    'skip$
  if$
  bracket.state close.brackets = % urlbst
    { "]" * }
    'skip$
  if$
  fin.entry.original
}

% Webpage entry type.
% Title and url fields required;
% author, note, year, month, and lastchecked fields optional
% See references
%   ISO 690-2 http://www.nlc-bnc.ca/iso/tc46sc9/standard/690-2e.htm
%   http://www.classroom.net/classroom/CitingNetResources.html
%   http://neal.ctstateu.edu/history/cite.html
%   http://www.cas.usf.edu/english/walker/mla.html
% for citation formats for web pages.
FUNCTION {webpage}
{ output.bibitem
  author empty$
    { editor empty$
        'skip$  % author and editor both optional
        { format.editors output.nonnull }
      if$
    }
    { editor empty$
        { format.authors output.nonnull }
        { "can't use both author and editor fields in " cite$ * warning$ }
      if$
    }
  if$
  new.block
  title empty$ 'skip$ 'possibly.setup.inlinelink if$
  format.title "title" output.check
  inbrackets onlinestring output
  new.block
  year empty$
    'skip$
    { format.date "year" output.check }
  if$
  % We don't need to output the URL details ('lastchecked' and 'url'),
  % because fin.entry does that for us, using output.web.refs.  The only
  % reason we would want to put them here is if we were to decide that
  % they should go in front of the rather miscellaneous information in 'note'.
  new.block
  note output
  fin.entry
}
% ...urlbst to here


FUNCTION {article}
{ output.bibitem
  format.authors "author" output.check
  new.block
  title empty$ 'skip$ 'possibly.setup.inlinelink if$              % urlbst
  format.title "title" output.check
  new.block
  crossref missing$
    { #1 'makeinlinelink :=                                       % PPGCosmoN added. Forces the use of inline link.
      possibly.setup.inlinelink journal "journal" output.check    % PPGCosmoN changed. The link is put on the journal name.
      format.vol.page output                                       % PPGCosmoN replaced. It was format.vol.num.pages .
      #1 'isyear :=
      format.date "year" output.check ")" *
      #0 'isyear :=
    }
    { format.article.crossref output.nonnull
      format.pages output
    }
  if$
  new.block
  note output
  fin.entry
}

FUNCTION {book}
{ output.bibitem
  author empty$
    { format.editors "author and editor" output.check }
    { format.authors output.nonnull
      crossref missing$
        { "author and editor" editor either.or.check }
        'skip$
      if$
    }
  if$
  new.block
  title empty$ 'skip$ 'possibly.setup.inlinelink if$ % urlbst
  format.btitle "title" output.check
  crossref missing$
    { format.bvolume output
      new.block
      format.number.series output
      new.sentence
      publisher "publisher" output.check
      address output
    }
    { new.block
      format.book.crossref output.nonnull
    }
  if$
  format.edition output
  format.date "year" output.check
  new.block
  note output
  fin.entry
}

FUNCTION {booklet}
{ output.bibitem
  format.authors output
  new.block
  title empty$ 'skip$ 'possibly.setup.inlinelink if$ % urlbst
  format.title "title" output.check
  howpublished address new.block.checkb
  howpublished output
  address output
  format.date output
  new.block
  note output
  fin.entry
}

FUNCTION {inbook}
{ output.bibitem
  author empty$
    { format.editors "author and editor" output.check }
    { format.authors output.nonnull
      crossref missing$
        { "author and editor" editor either.or.check }
        'skip$
      if$
    }
  if$
  new.block
  title empty$ 'skip$ 'possibly.setup.inlinelink if$ % urlbst
  format.btitle "title" output.check
  crossref missing$
    { format.bvolume output
      format.chapter.pages "chapter and pages" output.check
      new.block
      format.number.series output
      new.sentence
      publisher "publisher" output.check
      address output
    }
    { format.chapter.pages "chapter and pages" output.check
      new.block
      format.book.crossref output.nonnull
    }
  if$
  format.edition output
  format.date "year" output.check
  new.block
  note output
  fin.entry
}

FUNCTION {incollection}
{ output.bibitem
  format.authors "author" output.check
  new.block
  title empty$ 'skip$ 'possibly.setup.inlinelink if$ % urlbst
  format.title "title" output.check
  new.block
  crossref missing$
    { format.in.ed.booktitle "booktitle" output.check
      format.bvolume output
      format.number.series output
      format.chapter.pages output
      new.sentence
      publisher "publisher" output.check
      address output
      format.edition output
      format.date "year" output.check
    }
    { format.incoll.inproc.crossref output.nonnull
      format.chapter.pages output
    }
  if$
  new.block
  note output
  fin.entry
}

FUNCTION {inproceedings}
{ output.bibitem
  format.authors "author" output.check
  new.block
  title empty$ 'skip$ 'possibly.setup.inlinelink if$ % urlbst
  format.title "title" output.check
  new.block
  crossref missing$
    { format.in.ed.booktitle "booktitle" output.check
      format.bvolume output
      format.number.series output
      format.pages output
      address empty$
        { organization publisher new.sentence.checkb
          organization output
          publisher output
          format.date "year" output.check
        }
        { address output.nonnull
          format.date "year" output.check
          new.sentence
          organization output
          publisher output
        }
      if$
    }
    { format.incoll.inproc.crossref output.nonnull
      format.pages output
    }
  if$
  new.block
  note output
  fin.entry
}

FUNCTION {conference} { inproceedings }

FUNCTION {manual}
{ output.bibitem
  author empty$
    { organization empty$
        'skip$
        { organization output.nonnull
          address output
        }
      if$
    }
    { format.authors output.nonnull }
  if$
  new.block
  title empty$ 'skip$ 'possibly.setup.inlinelink if$ % urlbst
  format.btitle "title" output.check
  author empty$
    { organization empty$
        { address new.block.checka
          address output
        }
        'skip$
      if$
    }
    { organization address new.block.checkb
      organization output
      address output
    }
  if$
  format.edition output
  format.date output
  new.block
  note output
  fin.entry
}

FUNCTION {mastersthesis}
{ output.bibitem
  format.authors "author" output.check
  new.block
  title empty$ 'skip$ 'possibly.setup.inlinelink if$ % urlbst
  format.title "title" output.check
  new.block
  "Master's thesis" format.thesis.type output.nonnull
  school "school" output.check
  address output
  format.date "year" output.check
  new.block
  note output
  fin.entry
}

FUNCTION {misc}
{ output.bibitem
  format.authors output
  title howpublished new.block.checkb
  title empty$ 'skip$ 'possibly.setup.inlinelink if$ % urlbst
  format.title output
  howpublished new.block.checka
  howpublished output
  format.date output
  new.block
  note output
  fin.entry
  empty.misc.check
}

FUNCTION {phdthesis}
{ output.bibitem
  format.authors "author" output.check
  new.block
  title empty$ 'skip$ 'possibly.setup.inlinelink if$ % urlbst
  format.btitle "title" output.check
  new.block
  "PhD thesis" format.thesis.type output.nonnull
  school "school" output.check
  address output
  format.date "year" output.check
  new.block
  note output
  fin.entry
}

FUNCTION {proceedings}
{ output.bibitem
  editor empty$
    { organization output }
    { format.editors output.nonnull }
  if$
  new.block
  title empty$ 'skip$ 'possibly.setup.inlinelink if$ % urlbst
  format.btitle "title" output.check
  format.bvolume output
  format.number.series output
  address empty$
    { editor empty$
        { publisher new.sentence.checka }
        { organization publisher new.sentence.checkb
          organization output
        }
      if$
      publisher output
      format.date "year" output.check
    }
    { address output.nonnull
      format.date "year" output.check
      new.sentence
      editor empty$
        'skip$
        { organization output }
      if$
      publisher output
    }
  if$
  new.block
  note output
  fin.entry
}

FUNCTION {techreport}
{ output.bibitem
  format.authors "author" output.check
  new.block
  title empty$ 'skip$ 'possibly.setup.inlinelink if$ % urlbst
  format.title "title" output.check
  new.block
  format.tr.number output.nonnull
  institution "institution" output.check
  address output
  format.date "year" output.check
  new.block
  note output
  fin.entry
}

FUNCTION {unpublished}
{ output.bibitem
  format.authors "author" output.check
  new.block
  title empty$ 'skip$ 'possibly.setup.inlinelink if$ % urlbst
  format.title "title" output.check
  new.block
  note "note" output.check
  format.date output
  fin.entry
}

FUNCTION {default.type} { misc }

                           % PPGCosmoN: Several macros on month names and computational journals were here. They were removed.

READ

STRINGS { longest.label }

INTEGERS { number.label longest.label.width }

FUNCTION {initialize.longest.label}
{ "" 'longest.label :=
  #1 'number.label :=
  #0 'longest.label.width :=
}

FUNCTION {longest.label.pass}
{ number.label int.to.str$ 'label :=
  number.label #1 + 'number.label :=
  label width$ longest.label.width >
    { label 'longest.label :=
      label width$ 'longest.label.width :=
    }
    'skip$
  if$
}

EXECUTE {initialize.longest.label}

ITERATE {longest.label.pass}

FUNCTION {begin.bib}
{ preamble$ empty$
    'skip$
    { preamble$ write$ newline$ }
  if$
  "\begin{thebibliography}{"  longest.label  * "}" * write$ newline$
}

EXECUTE {begin.bib}

EXECUTE {init.urlbst.variables} % urlbst
EXECUTE {init.state.consts}

ITERATE {call.type$}

FUNCTION {end.bib}
{ newline$
  "\end{thebibliography}" write$ newline$
}

EXECUTE {end.bib}

%%% PPGCosmoThesis document class v 1.0
% Implemented by Davi C. Rodrigues ([email protected])
%
% Some features of this class use codes that were adapted from examples
% that can be freely found in tex.stackexchange.com. Some inspiration from
% University of Oslo latex template can also be found here.
% (https://www.overleaf.com/latex/templates/phduio-monograph/wvstjttnywvr)

\NeedsTeXFormat{LaTeX2e}
\ProvidesClass{PPGCosmoThesis}[2020/09/13 Class for PhD theses at PPGCosmo/UFES]

%%%%%%%%%%%%%%%%%%%%%%%%%%%%% CLASS OPTIONS & LOADCLASS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%

\newif\ifapproved 
\newif\ifnoxparse

\DeclareOption{approved}{\approvedtrue} % generates a second page for the approved thesis.
\DeclareOption{noxparse}{\noxparsetrue} % does not load the xparse package.

\DeclareOption*{\PassOptionsToClass{\CurrentOption}{scrbook}}
% If an option is given when calling PPGCosmoThesis, it will be passed
% to the class scrbook, from which PPGCosmoThesis is based.


\ProcessOptions
\relax

\LoadClass[
	fontsize=11pt,
	DIV=13,              % compact option for the margins.
	oneside,
	headings=big,
	chapterprefix=true. % writes "Chapter" in front of the chapter number.
	]
	{scrbook}
% scrbook is part of the KOMA script and it is an improved book format.
% A4paper is the standard paper size, no need to specify it.


%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% PACKAGES %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
\usepackage{amsmath,amssymb}
\usepackage[
	breaklinks,
	backref=page,         % Option to see where a ref. was cited.
	colorlinks=true,
	linkcolor=lightblue,
	citecolor=lightblue,
	urlcolor=YellowOrange!90!black
	]
	{hyperref}
\usepackage{graphicx}
\usepackage[dvipsnames]{xcolor}
\usepackage[automark,headsepline]{scrlayer-scrpage} % Sets the headings in each page within the Koma script.

\ifnoxparse \else \usepackage{xparse} \fi
% xparse is only used for the extended \eqref definition.
% If you do not use \eqref with multiple arguments, use the option noxparse

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% BACKREF TEXT %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
\renewcommand*{\backref}[1]{}
\renewcommand*{\backrefalt}[4]{%
    \ifcase #1 Not cited.%
    \or        Cited on page~#2.%
    \else      Cited on pages~#2.%
    \fi}


%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% HEADER AND FOOTER %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

% Relevant for printing the page numbers in the desired position.
\addtokomafont{pagenumber}{\oldstylenums}
\clearpairofpagestyles

% Defines variable \Chaptername that yields the current chapter name.
\let\Chaptermark\chaptermark
\def\chaptermark#1{\def\Chaptername{#1}\Chaptermark{#1}}

% Defines variable \Sectionname that yields the current section name (it is not currently used)
\let\Sectionmark\sectionmark
\def\sectionmark#1{\def\Sectionname{#1}\Sectionmark{#1}}

% The header and the footer
\ihead{\Chaptername}
\ohead{Section~\thesection}
\ofoot*{\pagemark} % the * forces the footer to be printed even in chapter pages, but not in titlepage .


% Defines tocHeader, a page style to be used in the table of contents
\newpairofpagestyles{tocHeader}{
	\ihead{Table of Contents}
	\ofoot*{\pagemark}
	}


% Defines biblioHeader, a page style to be used in the bibliography.
\newpairofpagestyles{biblioHeader}{
	\ihead{Bibliography}
	\ofoot*{\pagemark}
	}


%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% OTHER DEFINITIONS %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

\graphicspath{{figures/}}
\setcounter{secnumdepth}{3} % number subsubsections
\setcounter{tocdepth}{3} % list subsubsections
\definecolor{lightblue}{RGB}{17, 134, 192} % Matches the light blue part in UFES logo
\definecolor{darkblue}{RGB}{18, 52, 99} % Matches the dark blue part in UFES logo
\definecolor{journalcolor}{RGB}{110, 40, 110} % Color used in the bibliography for the journals names, it is used by PPGCosmoN.bst.


%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% CHAPTER LAYOUT %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
\KOMAoption{chapterprefix}{true}
\renewcommand*\raggedchapter{\centering}
\RedeclareSectionCommand[beforeskip=0pt,afterskip=8\baselineskip]{chapter}
\setkomafont{chapterprefix}{\normalsize\mdseries}
\renewcommand*{\chapterformat}{%
\chapappifchapterprefix{\nobreakspace} \thechapter \autodot%
  \IfUsePrefixLine{%
    \par\nobreak\vspace{-\parskip}\vspace{-.6\baselineskip}%
    \rule{0.9\textwidth}{.5pt}%
  }{\enskip}%
}
\renewcommand\chapterlineswithprefixformat[3]{%
  \MakeUppercase{#2}#3
}


%%%%%%%%%%%%%%%%%%%%%%%%%% EXPANDED eqref DEFINITION %%%%%%%%%%%%%%%%%%%%%%%%%%%%%
% Needs the xparse package.
% Allows the use of \eqref{label1, label2,..., labelLast}. Otherwise, \eqref only
% works with a single label.
% It is the equivalent of (\ref{label1}-\ref{labelLast}})
% This is a variation from a case that can be found in tex.stackexchange.

\ifnoxparse 
\else
	\ExplSyntaxOn
	\DeclareDocumentCommand{\eqref}{m}{\quinn_mref:n {#1}}
	\seq_new:N \l_quinn_mref_seq
	\cs_new:Npn \quinn_mref:n #1
	 {
	  \seq_set_split:Nnn \l_quinn_mref_seq { , } { #1 }
	  \seq_pop_right:NN \l_quinn_mref_seq \l_tmpa_tl
	  (
	  \seq_map_inline:Nn \l_quinn_mref_seq
	    { \ref{##1},\nobreakspace }
	  \exp_args:NV \ref \l_tmpa_tl
	  )
	 }
	\ExplSyntaxOff
\fi

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%% FIRST PAGES %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

%% New page elements

\newcommand{\@degree}{\large Thesis submitted as part of the requirements for the degree of \\ Doctor of Philosophy in Astronomy \& Physics}

\newcommand{\@supervisor}{}
\newcommand{\supervisor}[1]{\gdef\@supervisor{#1}}
\newkomafont{supervisor}{\normalfont\large}

\newcommand{\@supervisoraddress}{}
\newcommand{\supervisoraddress}[1]{\gdef\@supervisoraddress{#1}}

\newcommand{\@cosupervisor}{}
\newcommand{\cosupervisor}[1]{\gdef\@cosupervisor{#1}}

\newcommand{\@cosupervisoraddress}{}
\newcommand{\cosupervisoraddress}[1]{\gdef\@cosupervisoraddress{#1}}

\newcommand{\@thesisyear}{}
\newcommand{\thesisyear}[1]{\gdef\@thesisyear{#1}}

\newcommand{\@dedicatory}{}
\newcommand{\dedicatory}[1]{\gdef\@dedicatory{#1}}

\newcommand{\@banca}{}
\newcommand{\banca}[1]{\gdef\@banca{#1}}

%% Builds the first pages, which are called by the user through \maketitle
\renewcommand{\maketitle}
{
	% FIRST PAGE
	\begin{titlepage}
		\sffamily
		\frontmatter         % pages are numbered using i, ii, iii...
		\centering

		\begin{figure}[h]
			\centering
			\includegraphics[width=2.5cm]{logo-ufes.png}
		\end{figure}
		\noindent
		{\textbf{\huge Universidade Federal do Espírito Santo}}\\[0.25cm]
		{\textbf{\Large Programa de Pós-Graduação em Astrofísica, Cosmologia e Gravitação}}\\

		\vspace{1cm}
		\begin{center}
			\vspace{1cm}
			\textcolor{lightblue}{\textbf{\huge \@title}}\\
			\vspace{1cm}
			\textbf{\textcolor{black}{\Large \@author}}\\
			\vspace{4cm}
			\@degree
		\end{center}
		\vfill
		\begin{tabular}{ll}
			{\large Supervisor:} & \@supervisor\\
				& \textit{\@supervisoraddress} \\[.2cm]
			{\large Co-supervisor:} & \@cosupervisor\\
				& \textit{\@cosupervisoraddress}
		\end{tabular}
		\vspace{1cm}
		\begin{center}
			\includegraphics[width=3.0cm]{logo-ppgcosmo.png}\\[0.5cm]
			\textbf{\Large \@thesisyear}
		\end{center}

	\end{titlepage}

	\ifapproved
		% SECOND PAGE - Approved version 
		\begin{titlepage}
			\sffamily
			\vspace{2cm}
			\noindent
			{\textbf{\large Universidade Federal do Espírito Santo}}\\
			\textbf{\large Centro de Ciências Exatas}\\
			{{\large Programa de Pós-Graduação em Astrofísica, Cosmologia e Gravitação}}
	
			\vspace{2cm}
	
			\noindent
			\textbf{\large \@title}\\
	
			\noindent
			{\large \@author}
	
			\vspace{2cm}
	
			\noindent
			\begin{minipage}{0.75\textwidth}
				\noindent
				A presente tese ``\textit{\@title}'' foi submetida por  \mbox{\textit{\@author}}  ao PPGCosmo, tendo sido  apresentada e aprovada no ano de {\@thesisyear} como parte dos requisitos para a obtenção do título de Doutor em Astronomia e Física.
	
				\vspace{2cm}
				
				Comissão avaliadora:\\
				
				\@banca
				
				\noindent
			\end{minipage}
		\end{titlepage}

	\else
		% SECOND PAGE - Submitted version 
		\begin{titlepage}
			\sffamily
			\vspace{2cm}
			\noindent
			{\textbf{\large Universidade Federal do Espírito Santo}}\\
			\textbf{\large Centro de Ciências Exatas}\\
			{{\large Programa de Pós-Graduação em Astrofísica, Cosmologia e Gravitação}}
	
			\vspace{2cm}
	
			\noindent
			\textbf{\large \@title}\\
	
			\noindent
			{\large \@author}
	
			\vspace{2cm}
	
			\noindent
			\begin{minipage}{0.75\textwidth}
				\noindent
				A presente tese ``\textit{\@title}'' foi submetida no ano de {\@thesisyear} ao PPGCosmo por \textit{\@author} como parte dos requisitos para a obtenção do título de Doutor em Astronomia e Física.
	
				\bigskip
	
				\noindent
				Caso esta tese venha a ser aprovada, esta folha deverá ser substituída pela correspondente de aprovação.
			\end{minipage}
		\end{titlepage}
	\fi

	% DEDICATORY
	\if\@dedicatory0 %i.e., if \@dedicatory=0 do nothing, otherwise do the dedicatory page.
	\else
		{
		\begin{titlepage}
			\vspace*{\stretch{3}}
			\begin{flushright}
			   \emph{\@dedicatory}
			\end{flushright}
			\vspace*{\stretch{1}}
		\end{titlepage}
		}
	\fi
	% ABSTRACT
	\begin{minipage}{0.90\textwidth}
		\chapter*{Abstract}
		\input{sections/abstract.tex}

		\hrulefill
	\end{minipage}
	\pagebreak

	% RESUMO
	\begin{minipage}{0.90\textwidth}
		\chapter*{Resumo}
		\input{sections/resumo.tex}

		\hrulefill
	\end{minipage}
	\pagebreak

	% ACKNOWLEDGEMENTS
	\begin{minipage}{0.95\textwidth}
		\input{sections/acknowledgements}
	\end{minipage}
	\pagebreak

	% TABLE OF CONTENTS
	\pagestyle{tocHeader}    % page style becomes the previously defined tocHeader
	{
	\hypersetup{linkcolor=darkblue} 
	\tableofcontents
	}

	\mainmatter              % pages start to be numbered by 1, 2, 3...
	
	\pagestyle{scrheadings} % page style returns to the standard.
}

The abstract goes here. \\ 

\chapter*{Acknowledgments / Agradecimentos}

This section does not need to be written in English. \\

Here you should acknowledge all those that contributed directly to the accomplishment of  this work. You may  add acknowledgements to indirect contributions. \\

By the end, you should acknowledge any relevant funding for the work of this thesis. Some funding agencies have strict rules on how to express these acknowledgements.

\chapter{Further details on the post-Minkowskian expasion}


An appendix goes here.

\chapter{The code on the $H_0$ tension analysis}


Another appendix.

\chapter{Introduction} \label{chap:intro}

% If you want to use a fancy citation, here is an example:
%\begin{flushright}
%	\textit{Yours sincerely}\\
%	--- A. Einstein.
%\end{flushright}


\section{Introduction part 1} \label{sec:intro-1}
\section{Introduction part 2} \label{sec:intro-2}
We take the opportunity to cite \cite{Arnowitt:1962hi,  Akerib:2013tjd, Abbott:2016blz}.

\chapter{A chapter title goes here}

% If you want to add a fancy citation, here is an example:
%\begin{flushright}
%	\textit{I'm human.}\\
%	--- G. Samsa
%\end{flushright}
%\bigskip


% You may want to start with a brief description of the chapter.
% Here is an example:

%\begin{minipage}[c]{0.95\textwidth}
%	\textit{ \small A brief description of the chapter is not mandatory, but it can be welcome. This is the single piece of text that can precede the first section. This chapter is about....	}
%\end{minipage}

\section{Equations}
A section with some subsections.

\subsection{Two equations}

We know that 
\begin{equation}
	\boldsymbol{F} = m \boldsymbol{a}  \label{eq:ForceNewton}
\end{equation}
and
\begin{equation}
	G_{\mu \nu} = 8 \pi G  \, T_{\mu \nu} \, . \label{eq:EinsteinEq}
\end{equation}

Equations \eqref{eq:ForceNewton} and \eqref{eq:EinsteinEq} are both very important. You may also group the equations inside \verb!\eqref!: Naturally, eqs.~\eqref{eq:ForceNewton, eq:EinsteinEq} are both very important. There is no contraction \cite{Ade:2015xua, 0521857937, Abbott:2016blz}.

You can insert figures, as Figure~\ref{fig:ppgcosmologo}.

\begin{figure}[h]
 	\centering
	\includegraphics[width=0.2\textwidth]{logo-ppgcosmo.png}
	\caption{PPGCosmo logo.}
	\label{fig:ppgcosmologo}
\end{figure}

\subsection{Particular cases}
Sometimes it is relevant to cite other sections, see for instance Section \ref{sec:intro-2}.

\section{Another section}



\section{Chapter conclusions}

% Partial conclusions by the end of a chapter may be welcome.

\chapter{Conclusions}

\begin{minipage}[c]{0.95\textwidth}
	\textit{The sections below are suggestions.}
\end{minipage}



\section{Summary of achievements}


\section{Prospective directions}

	Versão em português do \textit{abstract}.

%
% You can use this file as a template for your thesis.
%
% Directory structure:
% PPGCosmoThesis requires two subfolders: "figures" and "sections".
%
% All the figures should be inserted in the folder "figures".
%
% The files abstract.tex, resumo.tex and acknowledgements.tex must be 
% in the folder "sections".
%
% By Davi Rodrigues. September, 2020.
%

\documentclass{PPGCosmoThesis}
% After the thesis' defense approval, use the option "approved". 
 
%%%%%%%%%%%%%%%%%%%%% ADDITIONAL PACKAGES %%%%%%%%%%%%%%%%%%%%%%%%%%
% PPGCosmoThesis already uses the following packages: 
% amsmath, amssymb, hyperref, graphicx, xcolor, scrlayer-scrpage and xparse
% If you need additional packages, put them here.




%%%%%%%%%%%%%%%%%% USER DEFINITIONS AND OTHER OPTIONS %%%%%%%%%%%%%%%%%%%%%
\bibliographystyle{PPGCosmoN} 
% PPGCosmoN is recommended. 
% Other options include unsrturl, abbrvurl, apacite (requires \usepackage{apacite})...

\includeonly{
	sections/chapter1,
	sections/chapter2,
	sections/chapter3,
	sections/appendix1,
	sections/appendix2
	}
% \includeonly speeds up the typesettings after the first complete one.
% If the speed is not a concern, you can remove it.
% If \includeonly is used, all the chapter file names must be inserted. 


%%%%%%%%%%%%%%%%%%%%%%% BEGIN DOCUMENT %%%%%%%%%%%%%%%%%%%%%%%%%%%%
\begin{document}

\title{Your paper}
\author{Emmanuel Frion}
\thesisyear{2020}
\supervisor{Prof.~Nelson Pinto-Neto}
\supervisoraddress{Cosmo, Centro Brasileiro de Pesquisas Físicas (Brazil)}
\cosupervisor{Prof.~David Wands}
\cosupervisoraddress{ICG, University of Portsmouth (UK)}

\dedicatory{0} 
% The value of 0 does not print the dedicatory page. 
% Here is an example: \dedicatory{To whoever made this wonderful thesis template.}
% If needed, use \\ to break lines.


%\banca{
%	Prof. Dr. Nelson Pinto-Neto (CBPF), orientador,\\ 
%	Prof. Dr. David Wands (Portsmouth U., Inglaterra), co-orientador, \\  
%	Prof. Dr. Jaílson Souza de Alcaniz (ON), examinador externo,\\
%	Prof. Dr. Patrick Peter (IAP, França), examinador externo, \\
%	Prof. Dr. Santiago Esteban Perez Berliaffa (UERJ), examinador externo,\\
%	Prof. Dr. Davi Cabral Rodrigues (UFES), examinador interno, \\
%	Prof. Dr. Júlio César Fabris (UFES), examinador interno.
%	}
%
% The \banca content only appears if the option "approved" is used.

\maketitle

%%%%%%%%%%%%%%%%%%%%%%%%% THE CHAPTERS %%%%%%%%%%%%%%%%%%%%%%%%%%

\include{sections/chapter1}
\include{sections/chapter2}
\include{sections/chapter3}
\appendix
\include{sections/appendix1}
\include{sections/appendix2}
% ATTENTION: check if the file names match those in the \includeonly command.
% All the files must be saved with ".tex", but inside \include the extensions are omitted.


%%%%%%%%%%%%%%%%%%%%%%%%% BIBLIOGRAPHY %%%%%%%%%%%%%%%%%%%%%%%%%%

\pagebreak
\pagestyle{biblioHeader}
{
	\hypersetup{urlcolor=darkblue} 
	\bibliography{BibExample.bib}  % put the name of your bib file here.
}

\end{document}