Guidance, Navigation and Control (World Scientific)

% WSPC TPE BibTeX Style File -- version 1.0
% BibTeX version 0.99c, intended for LaTeX2e
%
% For support email Rajesh <[email protected]>
% World Scientific Publishing Co. Pte. Ltd.
%
% This style was made from 'abbrv.bst' with lots of tweaking to make
% it look like WSPC GNC.
%
% If you make bug fixes, improvements, etc. please send in yours
% comments and suggetions to Rajesh <[email protected]>
%
% Copying of this file is authorized only if either
% (1) you make absolutely no changes to your copy, including name, or
% (2) if you do make changes, you name it something other than
% btxbst.doc, plain.bst, unsrt.bst, alpha.bst, abbrv.bst and ws-tpe.bst.
% This restriction helps ensure that all standard styles are identical.

ENTRY
  { address
    author
    booktitle
    chapter
    edition
    editor
    howpublished
    institution
    journal
    key
    month
    note
    number
    organization
    pages
    publisher
    school
    series
    title
    type
    volume
    year
    url
  }
  {}
  { label }

INTEGERS { output.state before.all mid.sentence after.quote after.sentence
        after.quoted.block after.block }

FUNCTION {init.state.consts}
{ #0 'before.all :=
  #1 'mid.sentence :=
  #2 'after.quote :=
  #3 'after.sentence :=
  #4 'after.quoted.block :=
  #5 'after.block :=
}

FUNCTION {disp.msg.screen} { #1 }

FUNCTION {type.msg}
{ disp.msg.screen
     { "<ws-tpe.bst>"
       top$
       "World Scientific's Bibliography Style File for TPE"
       top$
       "version 1.0 (2005/06/16)"
       top$
       "-- by Rajesh"
       top$
       "<unSorted version, follows inhouse bib-pattern 5>"
       top$
     }
     { skip$ }
   if$
}

STRINGS { s t }

FUNCTION {output.nonnull}
{ 's :=
  output.state mid.sentence =
    { ", " * write$ }
    { output.state after.quote =
    { " " * write$ }
    { output.state after.block =
        { add.period$ write$
          newline$
          "\newblock " write$
        }
        { output.state before.all =
        'write$
        { output.state after.quoted.block =
            { write$
              newline$
              "\newblock " write$
            }
            { add.period$ " " * write$ }
          if$
        }
          if$
        }
      if$
    }
      if$
      mid.sentence 'output.state :=
    }
  if$
  s
}

FUNCTION {output}
{ duplicate$ empty$
    'pop$
    'output.nonnull
  if$
}

FUNCTION {output.check}
{ 't :=
  duplicate$ empty$
    { pop$ "empty " t * " in " * cite$ * warning$ }
    'output.nonnull
  if$
}

FUNCTION {output.bibitem}
{ newline$
  "\bibitem{" write$
  cite$ write$
  "}" write$
  newline$
  ""
  before.all 'output.state :=
}

FUNCTION {blank.sep}
{
 after.quote 'output.state :=
}

FUNCTION {fin.entry}
{ output.state after.quoted.block =
    'skip$
    'add.period$
  if$
  write$
  newline$
}

FUNCTION {new.block}
{ output.state before.all =
    'skip$
    { output.state after.quote =
    { after.quoted.block 'output.state := }
    { after.block 'output.state := }
      if$
    }
  if$
}

FUNCTION {new.sentence}
{ output.state after.block =
    'skip$
    { output.state before.all =
    'skip$
    { after.sentence 'output.state := }
      if$
    }
  if$
}

FUNCTION {not}
{   { #0 }
    { #1 }
  if$
}

FUNCTION {and}
{   'skip$
    { pop$ #0 }
  if$
}

FUNCTION {or}
{   { pop$ #1 }
    'skip$
  if$
}

FUNCTION {new.block.checka}
{ empty$
    'skip$
    'new.block
  if$
}

FUNCTION {new.block.checkb}
{ empty$
  swap$ empty$
  and
    'skip$
    'new.block
  if$
}

FUNCTION {new.sentence.checka}
{ empty$
    'skip$
    'new.sentence
  if$
}

FUNCTION {field.or.null}
{ duplicate$ empty$
    { pop$ "" }
    'skip$
  if$
}

FUNCTION {emphasize}
{ duplicate$ empty$
    { pop$ "" }
    { "{\em " swap$ * "}" * }
  if$
}

FUNCTION {bold}
{ duplicate$ empty$
    { pop$ "" }
    { "{\bf " swap$ * "}" * }
  if$
}

INTEGERS { nameptr namesleft numnames }

FUNCTION {format.names}
{ 's :=
  #1 'nameptr :=
  s num.names$ 'numnames :=
  numnames 'namesleft :=
    { namesleft #0 > }
    { s nameptr "{ff~}{vv~}{ll}{, jj}" format.name$ 't :=
      nameptr #1 >
    { namesleft #1 >
        { ", " * t * }
        { numnames #2 >
        { "" * }
        'skip$
          if$
          t "others" =
        { " {\em et~al.}" * }
        { " and " * t * }
          if$
        }
      if$
    }
    't
      if$
      nameptr #1 + 'nameptr :=
      namesleft #1 - 'namesleft :=
    }
  while$
}

FUNCTION {format.authors}
{ author empty$
    { "" }
    { author format.names }
  if$
}

FUNCTION {format.editors}
{ editor empty$
    { "" }
    { editor format.names
      editor num.names$ #1 >
    { " (eds.)" * }
    { " (ed.)" * }
      if$
    }
  if$
}

FUNCTION {format.eeditors}
{ editor empty$
    { "" }
    { editor num.names$ #1 >
    { " eds." * }
    { " ed." * }
      if$
    editor format.names}
  if$
}

FUNCTION {format.title}
{ title empty$
    { "" }
    { title }
  if$
}

FUNCTION {format.title.p}
{ title empty$
    { "" }
    { title }
  if$
}

FUNCTION {n.dashify}
{ 't :=
  ""
    { t empty$ not }
    { t #1 #1 substring$ "-" =
    { t #1 #2 substring$ "--" = not
        { "--" *
          t #2 global.max$ substring$ 't :=
        }
        {   { t #1 #1 substring$ "-" = }
        { "-" *
          t #2 global.max$ substring$ 't :=
        }
          while$
        }
      if$
    }
    { t #1 #1 substring$ *
      t #2 global.max$ substring$ 't :=
    }
      if$
    }
  while$
}

FUNCTION {format.mdate}
{ year empty$
    { month empty$
    { "" }
    { "there's a month but no year in " cite$ * warning$
      month
    }
      if$
    }
    { month empty$
    { " (" year * ")" *}
    { " (" * month * "" year * ")" *}
      if$
    }
  if$
}

FUNCTION {format.date}
{ year empty$
    { month empty$
    { "" }
    { "there's a month but no year in " cite$ * warning$
      month
    }
      if$
    }
    { month empty$
    { " (" year * ")" *}
    { " (" * month * "" year * ")" *}
      if$
    }
  if$
}

FUNCTION {format.btitle}
    { title emphasize }

FUNCTION {tie.or.space.connect}
{ duplicate$ text.length$ #3 <
    { "~" }
    { " " }
  if$
  swap$ * *
}

FUNCTION {empty.field.to.null.string}
{ duplicate$ empty$
    { pop$ "" }
    { skip$ }
  if$
}

FUNCTION {either.or.check}
{ empty$
    'pop$
    { "can't use both " swap$ * " fields in " * cite$ * warning$ }
  if$
}

FUNCTION {format.bvolume}
{ series empty$
   { "" }
    { volume empty$
       {series *}
       {", " * series * "Vol.~" volume *}
      if$
    }
  if$
}

FUNCTION {format.number.series}
{ volume empty$
    { number empty$
    { series field.or.null }
    { output.state mid.sentence =
        { "no.~" }
        { "No.~" }
      if$
      number *
      series empty$
        { "there's a number but no series in " cite$ * warning$ }
        { " in " * series * }
      if$
    }
      if$
    }
    { "" }
  if$
}

FUNCTION {format.edition}
{ edition empty$
    { "" }
    { output.state mid.sentence =
    { edition "l" change.case$ " edn." * }
    { edition "t" change.case$ " edn." * }
      if$
    }
  if$
}

INTEGERS { multiresult }

FUNCTION {multi.page.check}
{ 't :=
  #0 'multiresult :=
    { multiresult not
      t empty$ not
      and
    }
    { t #1 #1 substring$
      duplicate$ "-" =
      swap$ duplicate$ "," =
      swap$ "+" =
      or or
    { #1 'multiresult := }
    { t #2 global.max$ substring$ 't := }
      if$
    }
  while$
  multiresult
}

FUNCTION {first.page.number}
{ 't :=
  ""
    { t "" =
        { #0 }
        { t #1 #1 substring$ "-" = not }
      if$
    }
    { t #1 #1 substring$ *
      t #2 global.max$ substring$ 't :=
    }
  while$
}

FUNCTION {format.pages}
{ pages empty$
    { "" }
    { pages multi.page.check
        { pages first.page.number}
        { "p." pages tie.or.space.connect }
      if$
    }
  if$
}

FUNCTION {format.ppages}
{ pages empty$
    { "" }
    { pages multi.page.check
        { "pp." pages n.dashify tie.or.space.connect }
        { "p." pages tie.or.space.connect }
      if$
    }
  if$
}

FUNCTION {format.number}
{ number empty$
    { "" }
    { "("  number * ")" *}
  if$
}

FUNCTION {format.journal.volume.number}
{ journal empty$
    { "empty " t * " in " * cite$ * warning$ ""}
    { journal emphasize }
  if$
  volume empty$      %% warning if no volume
    { "empty volume in " cite$ * warning$ " " *}
    { " " * volume bold *}      %% make volume bold
%%    { "vol.~" volume * }
  if$
%  month empty$
%    { format.number *}
%    'skip$
%  if$
}

FUNCTION {format.series.volume.number}
{ series empty$
   { "" }
    { volume empty$
       {series *}
       {", " * series * "Vol.~" volume *}
      if$
    }
  if$
  month empty$
    { format.number *}
    'skip$
  if$
}

% following not used
FUNCTION {format.volume}
{ volume empty$
    { "" }
    { volume bold }            
%%    { "vol.~" volume * }
  if$
}

FUNCTION {format.chapter.pages}
{ chapter empty$
    'format.ppages
    { type empty$
    { "ch.~" chapter * }
    { type "l" change.case$ chapter tie.or.space.connect }
      if$
      pages empty$
    'skip$
    { ", " * format.ppages * }
      if$
    }
  if$
}

FUNCTION {format.chapter.ppages}
{ chapter empty$
    'format.ppages
    { type empty$
    { "ch.~" chapter * }
    { type "l" change.case$ chapter tie.or.space.connect }
      if$
      pages empty$
    'skip$
    { ", " * format.ppages * }
      if$
    }
  if$
}

FUNCTION {format.in.ed.booktitle}
{ booktitle empty$
    { "" }
    { ", in {\em " * booktitle * "\/}, " *
       format.eeditors
    }
  if$
}

FUNCTION {format.thesis.type}
{ type empty$
    'skip$
    { pop$
      output.state after.block =
    { type "t" change.case$ }
    { type "l" change.case$ }
      if$
    }
  if$
}

FUNCTION {empty.misc.check}
{ author empty$ title empty$ howpublished empty$ 
  month empty$ year empty$ note empty$
  and and and and and
    { "all relevant fields are empty in " cite$ * warning$ }
    'skip$
  if$
}

FUNCTION {format.tr.number}
{ type empty$
    { "Tech. Rep." }
    'type
  if$
  number empty$
    { "l" change.case$ }
    { number tie.or.space.connect }
  if$
}


FUNCTION {format.paddress}
{ address empty$
    { "" }
    { "(" address * ")" * }
  if$
}

FUNCTION {format.article.crossref}
{ key empty$
    { journal empty$
    { "need key or journal for " cite$ * " to crossref " * crossref *
      warning$
      ""
    }
    { " in {\em " journal * "\/}" * }
      if$
    }
    { " in " key * }
  if$
  "\cite{" * crossref * "}" *
}

FUNCTION {format.crossref.editor}
{ editor #1 "{vv~}{ll}" format.name$
  editor num.names$ duplicate$
  #2 >
    { pop$ " {\em et~al.}" * }
    { #2 <
    'skip$
    { editor #2 "{ff }{vv }{ll}{ jj}" format.name$ "others" =
        { " {\em et~al.}" * }
        { " and " * editor #2 "{vv~}{ll}" format.name$ * }
      if$
    }
      if$
    }
  if$
}

FUNCTION {format.book.crossref}
{ volume empty$
    { "empty volume in " cite$ * "'s crossref of " * crossref * warning$
      "In "
    }
    { "Vol.~" volume *
      " of " *
    }
  if$
  editor empty$
  editor field.or.null author field.or.null =
  or
    { key empty$
    { series empty$
        { "need editor, key, or series for " cite$ * " to crossref " *
          crossref * warning$
          "" *
        }
        { "{\em " * series * "\/}" * }
      if$
    }
    { key * }
      if$
    }
    { format.crossref.editor * }
  if$
  "\cite{" * crossref * "}" *
}

FUNCTION {format.incoll.inproc.crossref}
{ editor empty$
  editor field.or.null author field.or.null =
  or
    { key empty$
    { booktitle empty$
        { "need editor, key, or booktitle for " cite$ * " to crossref " *
          crossref * warning$
          ""
        }
        { " in {\em " booktitle * "\/}" * }   
      if$
    }
    { " in " key * }
      if$
    }
    { " in " format.crossref.editor * }   
  if$
  "\cite{" * crossref * "}" *
}

FUNCTION {push.url}
{}

FUNCTION {push.date}
% format: month year
{ year empty$
    { month empty$
        { "" }
        { "there's a month but no year in " cite$ * warning$
          month
        }
      if$
    }
    { month empty$
        { year }
        { month " " * year * }
      if$
    }
  if$
}


FUNCTION {format.address.date}
{ address empty$
    {year empty$ 
        { "" }
        { push.date *} 
        if$
    }
    { "(" address * ", " * year * ")" * }
  if$
}

FUNCTION {format.school.date}
{ school empty$
    {"school is missing " cite$ * warning$
    year empty$ 
        { "" }
        { push.date *} 
        if$
    }
    { "(" school * ", " * year * ")" * }
  if$
}

FUNCTION {push.address.publisher.year}
% the whole imprint
{ address empty$
    { publisher empty$
        { url empty$
            { year empty$ 
                { "" }
                { push.date } 
              if$
            }
            { 
              push.url
              year empty$
                { skip$ }
                { ", " * push.date * ")" * }
              if$
            }
          if$
        }
      { "(" publisher *
      year empty$
            { skip$ }
            { ", " * push.date * ")" * }
          if$
        }
      if$
    }
    { 
      publisher empty$
        { skip$ }
        { "(" publisher * ", " * address * }
      if$
      year empty$
    { ")" * }
    { ", " * push.date * ")" * }
      if$
    }
  if$
}

FUNCTION {article}
{ output.bibitem
  format.authors "author" output.check
  format.title "title" output.check
  crossref missing$
    { format.journal.volume.number output
      format.pages output
      blank.sep
      format.date "year" output.check
    }
    { format.article.crossref output.nonnull
      format.pages output
    }
  if$
  note output
  fin.entry
}

FUNCTION {book}
{ output.bibitem
  author empty$
    { format.editors "author and editor" output.check }
    { format.authors output.nonnull
      crossref missing$
    { "author and editor" editor either.or.check }
    'skip$
      if$
    }
  if$
  format.btitle "title" output.check
  crossref missing$
    { format.bvolume output
      format.number.series output
      format.edition output
      blank.sep      
      push.address.publisher.year "publisher" output.check
    }
    { new.block
      format.book.crossref output.nonnull
    }
  if$
  new.block
  note output
  fin.entry
}

FUNCTION {booklet}
{ output.bibitem
  format.authors output
  title empty$
    { "empty title in " cite$ * warning$
      howpublished new.sentence.checka
    }
    { howpublished empty$ not
      address empty$ month empty$ year empty$ and and
      or
    { format.title.p output.nonnull }
    { format.title output.nonnull }
      if$
    }
  if$
  howpublished output
  publisher empty$
  {format.address.date output}
  {push.address.publisher.year "publihser" output.check}
  if$
  new.block
  note output
  fin.entry
}

FUNCTION {inbook}
{ output.bibitem
  author empty$
    { format.editors "author and editor" output.check }
    { format.authors output.nonnull}
  if$
%  format.btitle "title" output.check
   format.title "title" output.check
  blank.sep
  format.in.ed.booktitle "booktitle" output.check
  crossref missing$
    { format.bvolume output
      blank.sep
      format.number.series output
      push.address.publisher.year "publisher" output.check
      address output
      format.chapter.ppages "chapter and pages" output.check      
    }
    { format.chapter.ppages "chapter and pages" output.check
      new.block
      format.book.crossref output.nonnull
    }
  if$
  format.edition output
  %new.block
  note output
  fin.entry
}

FUNCTION {incollection}
{ output.bibitem
  format.authors "author" output.check
  format.title "title" output.check
  blank.sep
  crossref missing$
    { format.in.ed.booktitle "booktitle or editor" output.check
     format.series.volume.number output
      blank.sep
      push.address.publisher.year "publisher" output.check
      blank.sep
      format.ppages output
      format.edition output
    }
    { format.incoll.inproc.crossref output.nonnull
      blank.sep
      format.ppages output
    }
  if$
  new.block
  note output
  fin.entry
}

FUNCTION {inproceedings}
{ output.bibitem
  format.authors "author" output.check
  format.title "title" output.check
  blank.sep
  crossref missing$
    { format.in.ed.booktitle output  %remove check for booktitle
      journal empty$
          {format.series.volume.number output}
          {format.journal.volume.number output}
     if$
  blank.sep     
        publisher empty$
            {format.address.date output}
            {push.address.publisher.year "publihser" output.check}
        if$
    }
    { format.chapter.ppages "chapter and pages" output.check
      new.block
      format.book.crossref output.nonnull
    }
  if$
  %new.block
  note output
  fin.entry
}

FUNCTION {conference} { inproceedings }

FUNCTION {manual}
{ output.bibitem
  author empty$
    { organization empty$
    'skip$
    { organization output.nonnull
      address output
    }
      if$
    }
    { format.authors output.nonnull }
  if$
  format.btitle "title" output.check
  author empty$
    { organization empty$
    { address new.block.checka
      address output
    }
    'skip$
      if$
    }
    { organization address new.block.checkb
      organization output
      address output
    }
  if$
  format.edition output
  format.date output
  new.block
  note output
  fin.entry
}

FUNCTION {mastersthesis}
{ output.bibitem
  format.authors "author" output.check
  format.title "title" output.check
  "Master's thesis" format.thesis.type output.nonnull
  %format.school.date "school" output.check
  school output
  blank.sep
  format.date output
  new.block
  note output
  fin.entry
}

FUNCTION {misc}
{ output.bibitem
  format.authors output
  title empty$
    { howpublished new.sentence.checka }
    { howpublished empty$ not
      month empty$ year empty$ and
      or
    { format.title.p output.nonnull }
    { format.title output.nonnull }
      if$
      blank.sep
    }
  if$
  howpublished output
  format.date output
  note output
  fin.entry
  empty.misc.check
}

FUNCTION {phdthesis}
{ output.bibitem
  format.authors "author" output.check
  format.title "title" output.check
  "PhD thesis" format.thesis.type output.nonnull
  school "school" output.check
  publisher empty$
  {format.address.date output}
  {push.address.publisher.year "publihser" output.check}
  if$
  format.ppages output
  new.block
  note output
  fin.entry
}

FUNCTION {proceedings}
{ output.bibitem
  editor empty$
    { organization output }
    { format.editors output.nonnull }
  if$
  format.btitle "title" output.check
  blank.sep  
  format.series.volume.number output   
  editor empty$
    'skip$
    { organization output }
  if$
   push.address.publisher.year "publisher" output.check
  new.block
  note output
  fin.entry
}

FUNCTION {techreport}
{ output.bibitem
  format.authors "author" output.check
  format.btitle "title" output.check
  format.tr.number output.nonnull
  institution "institution" output.check
  blank.sep
  address empty$
  {format.mdate output}
  {format.address.date output}
  if$
  note output
  fin.entry
  new.block  
}

FUNCTION {unpublished}
{ output.bibitem
  format.authors "author" output.check
  format.title.p "title" output.check
  note "note" output.check
  format.date output
  fin.entry
}

FUNCTION {default.type} { misc }

MACRO {jan} {"January"}

MACRO {feb} {"February"}

MACRO {mar} {"March"}

MACRO {apr} {"April"}

MACRO {may} {"May"}

MACRO {jun} {"June"}

MACRO {jul} {"July"}

MACRO {aug} {"August"}

MACRO {sep} {"September"}

MACRO {oct} {"October"}

MACRO {nov} {"November"}

MACRO {dec} {"December"}

MACRO {acmcs} {"ACM Computing Surveys"}

MACRO {acta} {"Acta Informatica"}

MACRO {cacm} {"Communications ACM"}

MACRO {ibmjrd} {"IBM J. Research and Development"}

MACRO {ibmsj} {"IBM Systems~J."}

MACRO {ieeese} {"IEEE Trans. Software Engineering"}

MACRO {ieeetc} {"IEEE Trans. Computers"}

MACRO {ieeetcad} {"IEEE Trans. Computer-Aided Design"}

MACRO {ipl} {"Information Processing Letters"}

MACRO {jacm} {"J.~ACM"}

MACRO {jcss} {"J.~Computer and System Sciences"}

MACRO {scp} {"Science of Computer Programming"}

MACRO {sicomp} {"SIAM J. Computing"}

MACRO {tocs} {"ACM Trans. Computer Systems"}

MACRO {tods} {"ACM Trans. Database Systems"}

MACRO {tog} {"ACM Trans. Graphics"}

MACRO {toms} {"ACM Trans. Mathematical Software"}

MACRO {toois} {"ACM Trans. Office Information Systems"}

MACRO {toplas} {"ACM Trans. Programming Languages and Systems"}

MACRO {tcs} {"Theoretical Computer Science"}

READ

EXECUTE {type.msg}

FUNCTION {sortify}
{ purify$
  "l" change.case$
}

INTEGERS { len }

FUNCTION {chop.word}
{ 's :=
  'len :=
  s #1 len substring$ =
    { s len #1 + global.max$ substring$ }
    { s }
  if$
}

FUNCTION {sort.format.names}
{ 's :=
  #1 'nameptr :=
  ""
  s num.names$ 'numnames :=
  numnames 'namesleft :=
    { namesleft #0 > }
    { nameptr #1 >
        { "   " * }
        { skip$ }
      if$
      s nameptr "{vv{ } }{ll{ }}{  ff{ }}{  jj{ }}" format.name$ 't :=
      nameptr numnames = t "others" = and
        { "et al" * }
        { t sortify * }
      if$
      nameptr #1 + 'nameptr :=
      namesleft #1 - 'namesleft :=
    }
  while$
}

FUNCTION {sort.format.title}
{ 't :=
  "A " #2
    "An " #3
      "The " #4 t chop.word
    chop.word
  chop.word
  sortify
  #1 global.max$ substring$
}

FUNCTION {author.sort}
{ author empty$
    { key empty$
        { "to sort, need author or key in " cite$ * warning$ "" }
        { key sortify }
      if$
    }
    { author sort.format.names }
  if$
}

FUNCTION {author.editor.sort}
{ author empty$
    { editor empty$
        { key empty$
            { "to sort, need author, editor, or key in " cite$ * warning$ "" }
            { key sortify }
          if$
        }
        { editor sort.format.names }
      if$
    }
    { author sort.format.names }
  if$
}

FUNCTION {author.organization.sort}
{ author empty$
    { organization empty$
        { key empty$
            { "to sort, need author, organization, or key in " cite$ * warning$ "" }
            { key sortify }
          if$
        }
        { "The " #4 organization chop.word sortify }
      if$
    }
    { author sort.format.names }
  if$
}

FUNCTION {editor.organization.sort}
{ editor empty$
    { organization empty$
        { key empty$
            { "to sort, need editor, organization, or key in " cite$ * warning$ "" }
            { key sortify }
          if$
        }
        { "The " #4 organization chop.word sortify }
      if$
    }
    { editor sort.format.names }
  if$
}

FUNCTION {author.organization.institution.sort}
{ author empty$
    { organization empty$
        { institution empty$
            { key empty$
                { "to sort, need author, organization, institution or key in " cite$ * warning$ "" }
                { key sortify }
              if$
            }
            { "The " #4 institution chop.word sortify }
          if$
        }
        { "The " #4 organization chop.word sortify }
      if$
    }
    { author sort.format.names }
  if$
}


FUNCTION {presort}
{ type$ "ieeetranbstctl" =
    { key empty$
        { "_" }
        { key sortify }
      if$
    }
    { type$ "book" =
      type$ "inbook" =
      or 
        { author.editor.sort }
        { type$ "proceedings" =
          type$ "periodical" =
          or
            { editor.organization.sort }
            { type$ "manual" =
              type$ "electronic" =
              type$ "misc" =
              or or
                { author.organization.sort }
                { type$ "standard" =
                   { author.organization.institution.sort }
                   { author.sort }
                 if$ 
                }
              if$
            }
          if$
        }
      if$
      "    "
      *
      year empty.field.to.null.string sortify
      *
      "    "
      *
      title empty.field.to.null.string
      sort.format.title
      *
    }
  if$
  #1 entry.max$ substring$
  'sort.key$ :=
}

%ITERATE {presort}

%SORT

STRINGS { longest.label }

INTEGERS { number.label longest.label.width }

FUNCTION {initialize.longest.label}
{ "" 'longest.label :=
  #1 'number.label :=
  #0 'longest.label.width :=
}

FUNCTION {longest.label.pass}
{ number.label int.to.str$ 'label :=
  number.label #1 + 'number.label :=
  label width$ longest.label.width >
    { label 'longest.label :=
      label width$ 'longest.label.width :=
    }
    'skip$
  if$
}

EXECUTE {initialize.longest.label}

ITERATE {longest.label.pass}

FUNCTION {begin.bib}
{ preamble$ empty$
    'skip$
    { preamble$ write$ newline$ }
  if$
  "\begin{thebibliography}{"  longest.label  * "}" * write$ newline$
}

EXECUTE {begin.bib}

EXECUTE {init.state.consts}

ITERATE {call.type$}

FUNCTION {end.bib}
{ newline$
  "\end{thebibliography}" write$ newline$
}

EXECUTE {end.bib}

%%
%% End of file
%% For Support: [email protected], [email protected]
%% ws-tpe.bst (C) World Scientific Publishing Co.

43 KB — too long to show here. It arrives with the project.

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% %% ws-gnc.tex   :   27-01-2026
%% Tex file to use with ws-gnc.cls written in Latex2E.
%% The content, structure, format and layout of this style file is the
%% property of World Scientific Publishing Co. Pte. Ltd.
%% Copyright 2026 by World Scientific Publishing Co.
%% All rights are reserved.
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%

%\documentclass[wsdraft]{ws-gnc}
\documentclass{ws-gnc}
\usepackage[super]{cite}
\usepackage{xcolor}
\usepackage[verbose]{hyperref}
\hypersetup{colorlinks=false,allbordercolors=blue,pdfborderstyle={/S/U/W 1}}
% \label, \ref and \cite commands are highly recommended

\usepackage{multicol,balance}

\begin{document}

\markboth{Authors' Names}{Paper Title}

%%%%%%%%%%%%%%%%%%%%% Publisher's Area please ignore %%%%%%%%%%%%%%%
\catchline{}{}{}{}{}
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

\title{Your paper}

\author{First Author$^{*}$ and Second Author$^{\dag,\ddag}$}

\address{$^{*}\!$University Department, University Name, Address, City, State ZIP/Zone, Country,\\
$^{\dag}\!$Group, Company, Address, City, State ZIP/Zone, Country}

\maketitle

\begin{history}
\received{xxx}
\revised{xxx}
\accepted{xxx}
\published{xxx}
\end{history}

\footnotetext{$^{\ddag}$Corresponding author.\\
\email{sauthor\_id@domain\_name}\\[3pt]
\copyright\ Technical Committee on Guidance, Navigation and Control, CSAA\\
This is an open access article under the CC BY-NC license (http://creativecommons.org/licenses/by-nc/4.0/).}

\vspace*{6pt}
\begin{minipage}[t]{1.5in}
\keywords{A list of 3--5 keywords are\\ to be supplied.}
\end{minipage}\hfill
\begin{minipage}[t]{5in}
\vspace*{-3pt}
\hrule height .15em
\begin{abstract}
The abstract should summarize the context,
content and conclusions of the paper. It should not contain any
references or displayed equations. Typeset the abstract in 8~pt
Times Roman with baselineskip of 10~pt.\\[-2pt]
\hrule height .15em
\end{abstract}
\end{minipage}

\vspace*{-2.5pc}

\begin{multicols}{2}
\section{The Main Text}
Contributions to {\it Guidance, Navigation and Control}
are to be in English. Authors are encouraged to have their
contribution checked for grammar. American spelling should be
used. Abbreviations are allowed but should be spelled out in full when
first used. Integers ten and below are to be spelled out. Italicize
foreign language phrases (e.g.~Latin, French).

For the title, try not to use more than three lines. Typeset the title in 20~pt Times
Roman, and boldface. Typeset author names in 14~pt Times Roman.
Use the footnote to indicate the present or permanent address of
the author. Affiliations are typeset in 9~pt Times\break italics. State completely without
abbreviations the\break affiliation and mailing address, including
country.

The text is to be typeset in 10~pt Times \hbox{Roman},
single-spaced with baselineskip of 13~pt. Text area is 7~in across and 9.6~in deep (including running title). Final pagination and insertion of running titles will be
done by the publisher.

\section{Major Headings}
Major headings should be typeset in boldface, with the first letter of
important words capitalized.

\subsection{Subheadings}
Sub-headings should be typeset in boldface italic and capitalize
the first letter of the first word only.

\subsubsection{Sub-subheadings}
Typeset sub-subheadings in medium face italic and\break capitalize the
first letter of the first word only.

\subsection{Numbering and spacing}
Sections, sub-sections and sub-subsections are numbered in
Arabic.  Use double spacing before all section headings, and
single spacing after section headings. Flush left all paragraphs
that follow after section headings.

\section{Lists of Items}
Lists are broadly classified into four major categories that can
randomly be used as desired by the author:
\begin{alphlist}[(d)]
\item Numbered list.
\item Lettered list.
\item Unnumbered list.
\item Bulleted list.
\end{alphlist}

\subsection{Numbered and lettered list}

\begin{enumerate}
\item[] The \verb|\begin{arabiclist}[]| command is used for the arabic
number list (arabic numbers appearing within parenthesis), e.g., (1),
(2), etc.

\smallskip

\item[] The \verb|\begin{romanlist}[]| command is used for the roman
number list (roman numbers appearing within parenthesis), e.g., (i),
(ii), etc.

\smallskip

\item[] The \verb|\begin{Romanlist}[]| command is used for the cap roman
\hbox{number list} (cap roman numbers appearing within parenthesis),
e.g., (I), (II), etc.

\smallskip

\item[] The \verb|\begin{alphlist}[]| command is used for the alphabetic
list (alphabets appearing within parenthesis), e.g., (a), (b), etc.

\smallskip

\item[] The \verb|\begin{Alphlist}[]| command is used for the cap
alphabetic list (cap alphabets appearing within parenthesis), e.g.,
(A), (B), etc.
\end{enumerate}
Note: For all the above mentioned lists (with the exception of
alphabetic list), it is obligatory to enter the last entry's number
in the list within the square bracket, to enable unit alignment.

\subsection{Bulleted and unnumbered list}

\begin{enumerate}
\item[] The \verb|\begin{itemlist}| command is used for the bulleted list.

\smallskip

\item[] The \verb|\begin{unnumlist}| command is used for creating\- the
  unnumbered list with the turnovers hangindent by 1\,pica.
\end{enumerate}

Lists may be laid out with each item marked by a bullet:
\begin{itemlist}
\item item one
\item item two.
\end{itemlist}

Items may also be numbered with lowercase\break numerals:
\begin{arabiclist}[(2)]
\item item one
\item item two
    \begin{romanlist}[(a)]
    \item lists within lists can be numbered with lowercase roman letters
    \item second item.
    \end{romanlist}
\end{arabiclist}

\section{Footnotes}
Footnotes should be numbered sequentially in superscript lowercase
roman letters.\footnote{Footnotes should be typeset in 8~pt Times Roman at the bottom of the page.}

\section{Mathematical Formulae}
\paragraph{Inline:}
For in-line formulae use \verb|\( ... \)| or \verb|$ ... $|. Avoid
built-up constructions, for example fractions and matrices, in
in-line formulae. Fractions in inline can be typed with a solidus, e.g., \verb|x+y/z=0|.

\paragraph{Display:}
Displayed equations should be numbered consecutively in
the paper, with the number set flush right and enclosed in
parentheses. For numbered display formulae, use the displaymath
environment:

\vspace*{5pt}
\verb|\begin{equation} ...| \verb|\end{equation}|.

\vspace*{5pt}
For unnumbered display formulae, use
\verb|\[ ... \]|. For numbered displayed,
one-line formulae always use the equation environment. Do not use
\verb|$$ ... $$|. For example, the input for
\begin{equation}
\mu(n, t) = \frac{\sum\limits^\infty_{i=1}1
(d_i < t, N(d_i) = n)}
{\int\limits^t_{\sigma=0}1(N(\sigma)=n)d\sigma}
\label{eq1}
\end{equation}

\noindent is:

\begin{verbatim}
\begin{equation}
\mu(n, t) = \frac{\sum\limits^\infty_{i=1}1
(d_i < t, N(d_i) = n)}
{\int\limits^t_{\sigma=0}1
(N(\sigma)=n)d\sigma}
\label{eq1}
\end{equation}
\end{verbatim}

For displayed multiline formulae, prefer using \verb|align| or \verb|align*| instead of \verb|eqnarray| environment.
\begin{verbatim}
\begin{align}
\zeta\mapsto\hat{\zeta} &=a\zeta+b\eta\,,\\
\eta\mapsto\hat{\eta} &=c\zeta+d\eta\,.
\label{eq2n3}
\end{align}
\end{verbatim}

\noindent produces:
\begin{eqnarray}
\zeta\mapsto\hat{\zeta}&=&a\zeta+b\eta\,,\\
\eta\mapsto\hat{\eta}&=&c\zeta+d\eta\,.
\label{eq2n3}
\end{eqnarray}

\LaTeX\ does not break long equations to make them fit within the
margins as it does with normal text. It is therefore up to you to
format the equation appropriately (if they overrun the margin.) This
typically requires some creative use of an eqnarray to get elements
shifted to a new line and to align nicely, e.g.,
\begin{align}
\left(1+x\right)^n =&\, 1 + nx + \frac{n\left(n-1\right)}{2!}x^2 \nonumber\\[3pt]
  &+ \frac{n\left(n-1\right)\left(n-2\right)}{3!}x^3 \nonumber\\[3pt]
  &+ \frac{n\left(n-1\right)\left(n-2\right)\left(n-3\right)}{4!}x^4\qquad \nonumber\\[3pt]
   &+ \ldots n{\rm th}.
\end{align}

Superscripts and subscripts that are words or abbreviations, as in
\( \pi_{\mathrm{low}} \), should be typed as roman letters;
this is done as \verb|\( \pi_{\mathrm{low}} \)|
instead of \( \pi_{low} \) done with \verb|\( \pi_{low} \)|

For geometric functions, e.g.,~exp, sin, cos, tan, etc., please use the macros
\verb|\sin, \cos, \tan|. These macros give proper spacing in mathematical formulae.

It is also possible to use the \AmS-\LaTeX{}
package, which can be obtained from the \AmS\ and various \TeX{}
archives.

Equations should be referred to in abbreviated form,
e.g.,~``Eq.~(\ref{eq1})'' or ``(2)''. In multiple-line equations,
the number should be given on the last line.

Displayed equations are to be centered on the page width. Standard
English letters like x are to appear as $x$ (italicized) in the
text if they are used as mathematical symbols. Punctuation marks
are used at the end of equations as if they appeared directly in
the text.

\enlargethispage{-0.5in} %ONLY NECESSARY

\section{Theorems and Definitions}
\LaTeX{} provides \verb|\newtheorem| to create new theorem
environments. The WSPC document styles contain a set of pre-defined
environments for theorems, definitions, proofs, remarks, etc., e.g.,
\begin{verbatim}
\begin{theorem}[Longo, 1998]
For a given $Q$-system...
\[
N = \{x \in N; T x = \gamma (x) T, T x^* =
\gamma (x^*) T\}\,,
\]
and $E_\Xi (\cdot) = T^* \gamma (\cdot) T$
gives a conditional expectation onto $N$
\end{theorem}
\end{verbatim}

\noindent generates

\begin{theorem}[Longo, 1998]\label{thm1}
For a given $Q$-system...
\[
N = \{x \in N; T x = \gamma (x) T, T x^* = \gamma (x^*) T\}\,,
\]
and $E_\Xi (\cdot) = T^* \gamma (\cdot) T$ gives a conditional
expectation onto $N$
\end{theorem}

\noindent and

\begin{verbatim}
\begin{theorem}
We have $\# H^2 (M \supset N) < \infty$ ...
\end{theorem}
\end{verbatim}

\noindent produces

\begin{theorem}\label{thm2}
We have $\# H^2 (M \supset N) < \infty$ for an inclusion\- $M \supset
N$ of factors of finite index.
\end{theorem}

\subsection{Proofs}
The WSPC document styles also provide a predefined proof environment
for proofs. The proof \hbox{environment} produces the heading
`Proof' with appropriate spacing and punctuation. It also appends a
`Q.E.D.' symbol, $\blacksquare$, at the end of a proof, e.g.

\begin{verbatim}
\begin{proof}
This is just an example.
\end{proof}
\end{verbatim}

\noindent to produce

\begin{proof}
This is just an example.
\end{proof}

The proof environment takes an argument in curly
braces, which allows you to substitute a different name for the standard
`Proof'. If you want to display, `Proof of Lemma', then write e.g.

\begin{verbatim}
\begin{proof}[Proof of Lemma]
This is just an example.
\end{proof}
\end{verbatim}

\noindent produces

\begin{proof}[Proof of Lemma]
This is just an example.
\end{proof}

\section{Floats}
\subsection{Tables}
Put tables and figures in text using the table and figure environments,
and position them near the first reference of the table or figure in
the text. Please avoid long captions in figures and tables.

\paragraph{Input:}

\begin{verbatim}
\begin{tablehere}
\tbl{... table caption ...}
{\begin{tabular}{@{}lcccr@{}}
\toprule
ID & $m$ & $R^2$ & $x_2$ & Times (s)\\
\colrule
11 & 100 & 3135 & 1138 & $<98$\\
...
15 & 100 & 3135 & 1138 & $<102$\\
\botrule
\end{tabular}}
\label{tbl1}
\end{tablehere}
\end{verbatim}

\noindent {\bf Output:}

\vspace*{-10pt}
\begin{tablehere}%[H]
\tbl{... table caption ...}
{\begin{tabular}{@{}lcccr@{}}
\toprule
ID & $m$ & $R^2$ & $x_2$ & Times (s)\\
\colrule
11 & 100 & 3135 & 1138 & $<98$\\[2pt]
12 & 100 & 3135 & 1138 & $<99$\\[2pt]
13 & 100 & 3135 & 1138 & $<100$\\[2pt]
14 & 100 & 3135 & 1138 & $<101$\\[2pt]
15 & 100 & 3135 & 1138 & $<102$\\ [2pt]
\botrule
\end{tabular}}
\label{tab:smtab}
\end{tablehere}

%\vspace*{-6pt}
By using \verb|\tbl| command in table environment, long captions will be justified to the table width while the short or single line captions are centered.
\verb|\tbl{table caption}{tabullar environment}|.

For most tables, the horizontal rules are obtained by:\\[8pt]
\begin{tabular}{@{}ll@{}}
{\bf toprule} & one rule at the top\\
{\bf colrule}& one rule separating column heads\\ & from data cells\\
{\bf botrule}& one bottom rule\\
{\bf Hline} & one thick rule at the top and\\ & bottom of the tables with multiple\\
& column heads\\[3pt]
\end{tabular}

\vspace*{6pt}
To avoid the rules sticking out at either end
of the table, add \verb|@{}| before the first and after the last descriptors, e.g., {@{}llll@{}}. Please avoid vertical rules in tables.
But if you think the vertical rule is a must,
you can use the standard \LaTeX{} \verb|tabular| environment.

Tables should have a uniform style throughout the
contribution. It does not matter how you place the
inner lines of the table, but we would prefer the border lines to be
of the style as shown in our sample tables.
For the inner lines of the table, it looks better
if they are kept to a minimum.

If tables need to extend over to a second page, the continuation
of the table should be preceded by a caption, e.g.,~``Table~1 ({\it
Continued})''.

\enlargethispage{-0.2in} %ONLY NECESSARY

\subsection{Figures}
A figure is obtained with the following commands

\begin{verbatim}
\begin{figurehere}
\centerline{\includegraphics[width=5cm}{gncf1}}
\caption{...caption here...}
\label{fig1}
\alttext{Description of the figure}
\end{figurehere}
\end{verbatim}

\begin{figurehere}
\centerline{\includegraphics[width=4cm]{gncf1}}
\caption{ ... caption here ... }
\label{fig1}
\alttext{Description of the figure}
\end{figurehere}

Figures are to be inserted in the text nearest their
first reference. If the publisher is required to reduce the figures, ensure that the
figures (including lettering and numbers) are large enough to be
clearly seen after reduction.

Figures are to be sequentially numbered with\break Arabic
numerals. The caption must be placed below the figure. For those
figures with multiple parts which appear on different pages, it is
best to place the full\break caption below the first part, and have
e.g.,~``Fig.~1\break ({\it Continued\/})'' below the last part.

Previously published material must be accompanied by written
permission from the author and publisher.

\begin{table*}[ht]
\vspace*{-6pt}
\tbl{Comparison of acoustic for frequencies for piston-cylinder problem.\vspace*{5pt}}
{\tabcolsep13pt\begin{tabular}{@{}cccc@{}} \toprule
& Analytical frequency & TRIA6-$S_1$ model &  \\[2pt]
Piston mass & (Rad/s) & (Rad/s) & \% Error$^{\text a}$ \\[2pt]
\colrule
1.0\hphantom{00} & \hphantom{0}281.0 & \hphantom{0}280.81 & 0.07 \\[2pt]
0.1\hphantom{00} & \hphantom{0}876.0 & \hphantom{0}875.74 & 0.03 \\[2pt]
0.01\hphantom{0} & 2441.0 & 2441.0\hphantom{0} & 0.0\hphantom{0} \\[2pt]
0.001 & 4130.0 & 4129.3\hphantom{0} & 0.16\\[2pt]
\botrule
\end{tabular}}
\begin{tabnote}
$^{\text a}$ Sample table footnote.\\
\end{tabnote}
\label{tbl2}
\end{table*}

\begin{figure*}[ht]
\centerline{\includegraphics[width=6.5in]{gncf2}}
\caption{The bifurcating response curves of system
$\alpha=0.5$, $\beta=1.8$, $\delta=0.2$, $\gamma=0$: (a)
$\mu=-1.3$ and (b) $\mu=0.3$.}
\label{fig2}
\alttext{Description of the figure}
\end{figure*}

The preferred graphics formats are TIF and Encapsulated PostScript
(EPS) for any type of image. Our \TeX\ installation requires EPS,
but we can easily convert TIF to EPS. Many other formats, e.g., PICT\break
(Macintosh), WMF (Windows) and various proprietary formats, are not
suitable. Even if we can read such files, there is no guarantee that
they will look the same on our systems as on yours.

Adjust the scaling of the figure until it is correctly positioned,
and remove the declarations of the lines and any anomalous spacing.

We recommend the use of single column-wide tables and figures wherever
possible. Tables and \hbox{figures} spanning two columns can be typeset
with the following\break environments:

\begin{itemlist}
\item \verb|table*| and
\item \verb|figure*|.
\end{itemlist}

\noindent {\bf Example:}\\[6pt]
\noindent {\it Table:}

\vspace*{-10pt}
\begin{verbatim}
\begin{table*}
\tbl{Comparison of ...}
{\begin{tabular}{@{}cccc@{}} \toprule
Piston mass & Analytical ...\\ \colrule
1.0... \\ 0.001... \\
\botrule
\end{tabular}}
\begin{tabnote}
$^{\text a}$ Sample table footnote.\\
\end{tabnote} \label{tbl2}
\end{table*}
\end{verbatim}

\enlargethispage{-0.2in} %ONLY NECESSARY

\begin{sidewaystable*}[!pht]
\tbl{Positive values of $X_0$ by eliminating $Q_0$ from
Eqs.~(15) and (16) for different values of the parameters $f_0$,
$\lambda_0$ and $\alpha_0$ in various dimension.\vspace*{5pt}}
{\tabcolsep13pt\begin{tabular}{@{}ccccccccccc@{}}
\toprule\\[-8pt]
{} &  & &\multicolumn{8}{c}{Positive roots ($X_0$)}\\[3pt]
\cline{4-11}\\[-6pt]
$f_0$ & $\lambda_0$ & $\alpha_0$ &4D &5D &6D &7D &8D &10D &12D &16D\\[3.5pt]
\hline\\[-6pt]
$-0.033$ &0.034 &0.1
&6.75507, &4.32936, &3.15991, &2.44524,
&1.92883, &0.669541, &--- &---\\[3.5pt]
&&&1.14476 &1.16321 &1.1879
&1.22434 &1.29065
&0.415056\\[7pt]
$-0.1$ &0.333 &0.2
&3.15662, &1.72737, &--- &--- &--- &--- &--- &---\\[3.5pt]
&&&1.24003 &1.48602\\[7pt]
$-0.301$ &0.302 &0.001
&2.07773, &--- &--- &--- &--- &--- &--- &---\\[3.5pt]
&&&1.65625\\[7pt]
$-0.5$ &0.51 &0.001
&--- &--- &--- &--- &--- &--- &--- &---\\[7pt]
0.1 &0.1
&2&1.667, &1.1946
&--- &--- &--- &--- &--- &---\\[3.5pt]
&&&0.806578 &0.858211\\[7pt]
0.1 &0.1 &10
&0.463679 &0.465426 &0.466489 &0.466499
&0.464947 &0.45438 &0.429651 &0.35278\\[7pt]
0.1 &1
&0.2
&--- &--- &--- &--- &--- &--- &--- &---\\[7pt]
0.1 &5
&5&--- &--- &--- &--- &--- &--- &--- &---\\[7pt]
1 &0.001 &2
&0.996033, &0.968869, &0.91379, &0.848544,&0.783787, &0.669541,
&0.577489, &---\\[3.5pt]
&&&0.414324 &0.41436 &0.414412 &0.414489 &0.414605
&0.415056 &0.416214\\[7pt]
&0.001 &0.2
&0.316014, &0.309739, &--- &--- &--- &--- &--- &---\\[3.5pt]
&&&0.275327 &0.275856\\[7pt]
&0.1
&5
&0.089435 &0.089441 &0.089435 &0.089409 &0.08935
&0.089061 &0.088347 &0.084352\\[7pt]
&1 &3&0.128192 &0.128966 &0.19718, &0.169063, &0.142103,
&--- &--- &---\\[3.5pt]
&&&& &0.41436 &0.414412 &0.414489\\[3pt]
\Hline
\end{tabular}}\label{tbl3}
\end{sidewaystable*}

\noindent {\it Figure:}
\begin{verbatim}
\begin{figure*}
\centerline{\includegraphics[width=6in]{gncf2}}
\caption{The bifurcating response ...}
\label{fig2}
\alttext{Description of the figure}
\end{figure*}
\end{verbatim}

Very large figures and tables should be placed on a separate page
by themselves. Landscape tables and figures can be typeset with the following environments:

\begin{itemlist}
\item \verb|sidewaystable| and
\item \verb|sidewaysfigure|.
\end{itemlist}

\noindent {\bf Example:}

\begin{verbatim}
\begin{sidewaystable*}
\tbl{Positive values of ...}
{\begin{tabular}{@{}ccccccccccc@{}}
...
\end{tabular}}
\label{tbl3}
\end{sidewaystable*}
\end{verbatim}

\section{Citations}
We have used \verb|\bibitem| to produce the bibliography. Citations
in the text use the labels defined in the bibitem declaration, e.g.,
the first paper by Duan\cite{2} is cited using the command
\verb|\cite{1}|. Bibitem labels should be unique.

For multiple citations, do not use \verb|\cite{1}|, \verb|\cite{2}|, but use
\verb|\cite{1,2}| instead.

When the reference forms part of the sentence, it should not be
typed in superscripts, e.g.,

\begin{itemlist}
\item ``One can show from Ref.~\refcite{1} that $\ldots$'',
\item ``See Refs.~\refcite{2} and \refcite{4} for more details.''
\end{itemlist}

This is done using the LaTeX command: ``\verb|Ref.~\refcite{name}|''.

\section*{Note Added}
A note can be added before Acknowledgments.

\section*{Acknowledgments}
This part should come before References.
Funding information may also be included here.

\section*{ORCID}
You are encouraged to include in your user information the ORCID (\url{https://orcid.org/}) or register for one if you don't have it. This ID will help to identify you in the researcher community and make it easier to keep track of all your publications.
Please provide a valid ORCID here, e.g.,

\noindent Josiah Carberry - \par \url{https://orcid.org/0000-0002-1825-0097}

\noindent Rajesh Babu - \par\url{https://orcid.org/0009-0006-0415-6880}

\setcounter{equation}{0}
\renewcommand{\theequation}{A.\arabic{equation}}
\section{Appendices}
\noindent Appendices should be used only
when absolutely necessary. They should come immediately before
References. If there is more than one appendix, number them
alphabetically. Number displayed equations occurring in the
appendix as (\ref{aeqn1}), (A.2), etc.:
\begin{equation}
\mu(n, t) = \frac{\sum\limits^\infty_{i=1} 1(d_i < t, N(d_i) = n)}
{\int\limits^t_{\sigma=0} 1(N(\sigma) = n)d\sigma}\,\,.
\label{aeqn1}
\end{equation}

\section*{References}
References in the text are to be numbered consecutively in
Arabic numerals, in the order of first appearance. They are to
be typed in superscripts after punctuation marks,
e.g.~``$\ldots$ in the statement.\cite{3}''

For journal titles, use the standard abbreviations, see \url{http://images.webofknowledge.com/images/help/WOS/A_abrvjt.html}. Typeset references in 9~pt Times Roman with line spacing of 11pt.
List references using the style shown in the following examples.

\newcounter{myctr}
\def\myitem{\refstepcounter{myctr}\bibfont\parindent0pt\hangindent13pt\themyctr.\enskip}

\enlargethispage{-0.2in} %ONLY NECESSARY

\subsubsection*{journal papers}
\myitem  Haibin Duan, Mengzhen Huo and Yuhui Shi, Limit-Cycle-Based Mutant Multi-Objective Pigeon-Inspired Optimization, {\it IEEE T. Evolut. Comput.} {\bf 24}(5), 948--959 (2020).

\myitem P\"arssinen, A., Jussila, J., Ryyn\"anen, J.,
Sumanen, L. and Halonen, K.  A. I., A 2-GHz Wide-Band Direct Conversion Receiver for WCDMA Applications,' {\it IEEE J. Solid-State Circuits} {\bf 34}, 1893 (1999).

\subsubsection*{authored books}
\myitem Haibin Duan and Haixin Qiu, {\it Unmanned Aerial Vehicle Swarm Autonomous Control Based on Swarm Intelligence} (Science Press, Beijing, 2018) (in Chinese).

\myitem Haibin Duan, Xiangyin Zhang and Chunfang Xu, {\it Bio-Inpsired Computing} (Science Press, Beijing, 2011).

\subsubsection*{edited books}
\myitem Jianxia Zhao, Haibin Duan, Yanjie Zhao, et al., Consensus Control of Manned-Unmanned Aerial Vehicle Swarm Based on Hierarchy Interaction of Pigeons, in {\it Advances in Guidance, Navigation and Control}, eds. Liang Yan, Haibin Duan and Xiang Yu (Springer, Singapore, 2021), pp. 39--89.

\subsubsection*{proceedings}
\myitem Jianxia Zhao, Haibin Duan, Lin Chen, and Mengzhen Huo, Leadership Hierarchy-Based Formation Control via Adaptive Chaotic Pigeon-Inspired Optimization, in {\it Proceedings of 2020 International Federation of Automatic Control} (Berlin, Germany, 2020), pp. 1231--1240.

\begin{thebibliography}{0}

\bibitem{1} Haibin Duan, Mengzhen Huo and Yuhui Shi, Limit-Cycle-Based Mutant Multi-Objective Pigeon-Inspired Optimization, {\it IEEE T. Evolut. Comput.} {\bf 24}(5), 948--959 (2020), \url{https://doi.org/10.1109/TEVC.2020.2983311}.

\bibitem{2} Richard J.. Lorentz and David B. Benson, Deterministic and Nondeterministic Flowchart Interpretations, {\it J. Comput. Syst. Sci.} {\bf 27}(3), 400--433 (1983), \url{https://doi.org/10.1016/0022-0000(83)90050-8}.

\bibitem{3} Jianxia Zhao, Haibin Duan, Yanjie Zhao, et al., Consensus Control of Manned-Unmanned Aerial Vehicle Swarm Based on Hierarchy Interaction of Pigeons, in {\it Advances in Guidance, Navigation and Control}, {\it J. Shanghai Jiaotong Univ.} {\bf 54}(9), 973--980 (2020), \url{https://doi.org/10.16183/j.cnki.jsjtu.2020.146}.

\bibitem{4} Jianxia Zhao, Haibin Duan, Lin Chen, and Mengzhen Huo, Leadership Hierarchy-Based Formation Control via Adaptive Chaotic Pigeon-Inspired Optimization, in {\it Proceedings of 2020 International Federation of Automatic Control} (Berlin, Germany, 2020), pp. 1231--1240.
\end{thebibliography}
\end{multicols}

\bigskip

\begin{multicols}{2}
\section*{Photo and Bibliography}
\includegraphics[width=1in,height=1.25in]{author1}
{\bf First-Author} received his/her M.S. and Ph.D. degrees from the University of Name, in Year1 and Year2, respectively. From Year3 to Year4, he/she was Researcher/Engineer/... at the Institute of Name, and worked on the project of Title. From Year5, he/she was Associate Professor, and became full Professor in Year6 at the University of Name. Now, he/she holds Position at the Faculty of XXX of the University of Name. He/she is also the President/Director of Organization/Society.

First-Author is the author of over X technical publications, proceedings, editorials and books.
His/her research interests include Mind topics, Body topics and Application topics. He/she is the coordinator of the collaborative research network on Humanoid Robots at the University of Name, Country. He/she is an active member of the Y Societies, and was the General Chair of Z Conferences in Country, and the Co-Chair of Z Conferences in Country.

\medskip

\includegraphics[width=1in,height=1.28in]{author2}
{\bf Second-Author} received his/her M.S. degree in XXX Engineering from the University of Name, Country, and his/her Ph.D. degree in XXX Engineering from the University of Name, Country, in Year1 and Year2, respectively. From Year3 to Year4, he/she was at the University of Name, as Assistant/Associate/Full Professor. He/she is currently an Assistant/Associate/Full Professor in the Department of XXX, the University of Name, Country. From Year5 to Year6, he/she also served as Director/Manager/... with the Institute/Center/... of Name, where he/she was responsible for research projects in the area of Topics.

Second-Author is the author of over X technical publications. His/her research interests include Mind topics, Body topics and Application topics.

\bigskip

\noindent{\itshape Note: The corresponding author should be pointed out in the CVs, such as \bfseries{Prof Wang is the corresponding author of this paper}.}

\end{multicols}
\end{document}

%\documentclass[wsdraft]{ws-gnc}
\documentclass{ws-gnc}

\usepackage{overcite,url}
\usepackage{xcolor}
\usepackage[verbose,hypertexnames=false]{hyperref}
\hypersetup{colorlinks=false,allbordercolors=blue,pdfborderstyle={/S/U/W 1}}
% \label, \ref and \cite commands are highly recommended

\begin{document}

\title{Using World Scientific's Bibliography Style File}

\markboth{WSPC}{Using World Scientific's Bibliography Style File}

\maketitle

\section{Usage}

\begin{center}
\tablefont
\tabcolsep16pt\begin{tabular}{@{}ll@{}}\toprule
\multicolumn{1}{c}{Database}  & \multicolumn{1}{c}{Sample citation}\\
\multicolumn{1}{c}{entry type}\\\colrule

article & ...text.\cite{best03,pier02,jame02}\\

proceedings & ...text.\cite{weis94}\\

inproceedings & ...text.\cite{gupt97}\\

book & ...text.\cite{rich60,jarl88}\\

edition & ...text.\cite{chur90}\\

editor & ...text.\cite{benh93}\\

series & ...text.\cite{bake72}\\

tech report & ...text\cite{hobb92} and ...text.\cite{bria84}\\

unpublished & ...text.\cite{hear94}\\

phd thesis & ...text.\cite{brow88}\\

masters thesis & ...text.\cite{lodh74}\\

incollection & ...text.\cite{dani73}\\

misc & ...text.\cite{davi93}\\
\botrule
\end{tabular}
\end{center}

\medskip
When the reference forms part of the sentence, it should not
be typed in superscripts, e.g.: ``One can show from
Ref.~\refcite{davi93} that $\ldots$''

\bibliographystyle{ws-gnc}
\bibliography{ws-sample}

\end{document} 

@manual{lamp87,
  author    =   "L. Lamport",
  title     =   "Make Index: An Index Processor For LaTeX",
  year      =   "1987",
  note      =   "\url{http://www.tug.org/tex-archive/indexing/makeindex/doc/makeindex.dvi}"}

@book{jarl88,
  author    =   "C. Jarlskog" ,
  title     =   "CP {V}iolation",
  publisher =   "World Scientific",
  address   =   "Singapore",
  year      =   "1988"}

@book{lamp94,
  author    =   "L. Lamport",
  title     =   "\LaTeX, A Document Preparation System",
  publisher =   "Addison-Wesley",
  address   =   "Reading, MA",
  year      =   "1994",
  edition   =   "2nd"}

@book{ams04,
  author    =   "\AmS",
  title     =   "\AmS-\LaTeX{} Version 2 User's Guide",
  publisher =   "American Mathematical Society",
  address   =   "Providence",
  year      =   "2004",
  note      =   "\url{http://www.ams.org/tex/amslatex.html}"}

@book{benh93,
  editor    =   "Fr\'ed\'eric Benhamou and Alain Colmerauer" ,
  title     =   "Constraint {L}ogic {P}rogramming, {S}elected {R}esearch",
  publisher =   "MIT Press",
  year      =   "1993"}

@book{rich60,
  author    =   "L. F. Richardson",
  title     =   "Arms and {I}nsecurity",
  publisher =   "Boxwood",
  address   =   "Pittsburg",
  pages     =   "200--253",
  year      =   "1960"}

@book{chur90,
  author    =   "R. V. Churchill and J. W. Brown",
  title     =   "Complex {V}ariables and {A}pplications",
  publisher =   "McGraw-Hill",
  pages     =   "215--253",
  year      =   "1990",
  edition   =   "5th"}

@inproceedings{gupt97,
  author    =   "R. K. Gupta and S. D. Senturia",
  title     =   "Pull-in Time Dynamics as a Measure of Absolute Pressure",
  booktitle =   "Proc. {IEEE} Int. Workshop on
                Microelectromechanical Systems ({MEMS}'97)",
  address   =   "Nagoya, Japan",
  month     =   jan,
  year      =   "1997",
  pages     =   "290-294",
    note = "\url{https://doi.org/10.1109/MEMSYS.1997.581830}"}

@proceedings{weis94,
  title     =   "Contemporary {P}roblems in {S}tatistical {P}hysics",
  booktitle =   "Contemporary {P}roblems in {S}tatistical {P}hysics",
  editor    =   "G. H. Weiss",
  publisher =   "SIAM, Philadelphia",
  year      =   "1994"}

@article{best03,
    author  =   "Westbury, Bruce W.",
     title  =   "{$R$}-Matrices and the {M}agic {S}quare",
   journal  =   "J. Phys. A",
  fjournal  =   "Journal of Physics A: Mathematical and General",
    volume  =   "36",
      year  =   "2003",
    number  =   "7",
     pages  =   "1947--1959",
      issn  =   "0305-4470",
     coden  =   "JPHAC5",
   mrclass  =   "17B10",
  mrnumber  =   "1 960 703",
  note = "\url{https://doi.org/10.1088/0305-4470/36/11/501}"}

@article{pier02,
    author  =   "Deligne, Pierre X. and Gross, Benedict H.",
     title  =   "On the Exceptional Series, and Its Descendants",
   journal  =   "C. R. Math. Acad. Sci. Paris",
  fjournal  =   "Comptes Rendus Math\'ematique. Acad\'emie des Sciences. Paris",
    volume  =   "335",
      year  =   "2002",
    number  =   "11",
     pages  =   "877--881",
      issn  =   "1631-073X",
   mrclass  =   "20Gxx",
  mrnumber  =   "1 952 563",
  note = "\url{https://doi.org/10.1016/S1631-073X(02)02590-6}"}

@article{jame02,
    author  =   "Landsberg, James M. and Manivel, L.",
     title  =   "Triality, Exceptional {L}ie Algebras and {D}eligne Dimension Formulas",
   journal  =   "Adv. Math.",
  fjournal  =   "Advances in Mathematics",
    volume  =   "171",
      year  =   "2002",
    number  =   "1",
     pages  =   "59--85",
      issn  =   "0001-8708",
     coden  =   "ADMTA4",
   mrclass  =   "17B20 (17B25)",
  mrnumber  =   "1 933 384",
mrreviewer  =   "Dmitri I. Panyushev",
note  =   "\url{https://doi.org/10.1006/aima.2002.2071}"}

@techreport{hobb92,
     author =   "John D. Hobby",
      title =   "{A User's Manual for MetaPost}",
       year =   "1992",
      month =   "apr",
   language =   "english",
institution =   "AT\&T Bell Laboratories",
    address =   "Murray Hill, New Jersey",
       date =   "April 1992",
     number =   "162",
     npages =   "ii+88~pages"}

@techreport{bria84,
     author =   "Kernighan, Brian W.",
      title =   "{PIC}---{A} Graphics Language for Typesetting",
       type =   "Computing Science Technical Report",
     number =   "116",
institution =   "AT\&T Bell Laboratories",
    address =   "Murray Hill, New Jersey",
       year =   "1984"}

@unpublished{hear94,
  author    =   "H. C. Heard and I. Y. Borg and N. L. Carter and C. B. Raleigh",
  title     =   "{VoQS: Voice Quality Symbols}",
  note      =   "Revised to 1994",
  year      =   "1994"}

@phdthesis{brow88,
  author    =   "Marcus E. Brown",
  title     =   "An Interactive Environment for Literate Programming",
  school    =   "Texas A\&M University",
  address   =   "TX, USA",
  pages     =   "ix + 102",
  month     =   "aug",
  year      =   "1988"}

@inbook{bake72,
  author    =   "D. W. Baker and N. L. Carter",
  year      =   "1972",
  editor    =   "H. C. Heard and I. Y. Borg and N. L. Carter and C. B. Raleigh",
  title     =   "Seismic {V}elocity {A}nisotropy {C}alculated for {U}ltramafic {M}inerals
                and {A}ggregates",
  booktitle =   "Flow and {F}racture of {R}ocks",
  publisher =   "Am. Geophys. Union",
  series    =   "Geophys. Mono.",
  volume    =   "16",
  pages     =   "157--166",
  note  =   "\url{https://doi.org/10.1029/GM016p0157}"}

@mastersthesis{lodh74,
  author    =   "Gunter Sergei Lodha",
  title     =   "Quantitative Interpretation of Airborne
                Electromagnetic Response for a Spherical Model",
  school    =   "University of Toronto",
  address   =   "Canada",
  year      =   "1974"}

@incollection{dani73,
  author    =   "Jones, Daniel",
  title     =   "{The Term `Phoneme'}",
  editor    =   "Jones, W. E. and Laver, J.",
  booktitle =   "Phonetics in Linguistics: A Book of Reading",
  publisher =   "Longman",
  address   =   "London",
  pages     =   "187--204",
  year      =   "1973"}

@misc{davi93,
  author    =   "Bill Davidsen",
  title     =   "{NETPBM}",
  year      =   "1993",
  note      =   "{ftp://ftp.wustl.edu/graphics/graphics/packages/{NetPBM}}"}