Journal of Advanced Manufacturing Systems (World Scientific)

@book{hawking_ellis_1973,
  place={Cambridge},
  series={Cambridge Monographs on Mathematical Physics},
  title={The Large Scale Structure of Space-Time},
  DOI={10.1017/CBO9780511524646},
  publisher={Cambridge University Press},
  author={Hawking, S. W. and Ellis, G. F. R.},
  year={1973},
  collection={Cambridge Monographs on Mathematical Physics}}

@misc{Leismathphys,
    author = "R. Leis",
    title = "Zur Entwicklung der angewandten Analysis und mathematischen Physik in den letzten hundert Jahren",
    note = " \url{https://www.iam.uni-bonn.de/fileadmin/user_upload/leis/DMV.pdf}" }

@book{ColBenh:93,
  editor    =   "Fr\'ed\'eric Benhamou and Alain Colmerauer" ,
  title     =   "Constraint {L}ogic {P}rogramming, {S}elected {R}esearch",
  publisher =   "MIT Press",
  year      =   "1993"}

@book{ArmsRace1,
  author    =   "L. F. Richardson",
  title     =   "Arms and {I}nsecurity",
  publisher =   "Boxwood",
  address   =   "Pittsburg",
  pages     =   "200--253",
  year      =   "1960"}

@book{ComplexVariables,
  author    =   "R. V. Churchill and J. W. Brown",
  title     =   "Complex {V}ariables and {A}pplications",
  publisher =   "McGraw-Hill",
  pages     =   "215--253",
  year      =   "1990",
  edition   =   "5th"}

@inproceedings{conftypical,
  author    =   "R. K. Gupta and S. D. Senturia",
  title     =   "Pull-in Time Dynamics as a Measure of Absolute Pressure",
  booktitle =   "Proc. {IEEE} Int. Workshop on
                Microelectromechanical Systems ({MEMS}'97)",
  address   =   "Nagoya, Japan",
  month     =   jan,
  year      =   "1997",
  pages     =   "290-294",
  note = "\url{https://doi.org/10.1109/MEMSYS.1997.581830}"}

@inproceedings{Moss94,
  author    =   "F. Moss",
  title     =   "Stochastic resonance: From the ice ages to the monkey's ear",
  pages     =   "205--253",
  year      =   "1994",
  crossref  =   "Weiss94",
note = "\url{https://doi.org/10.1137/1.9781611971552.ch5}"}

@proceedings{Weiss94,
  title     =   "Contem\-porary {P}roblems in {S}tatistical {P}hysics",
  booktitle =   "Contemporary {P}roblems in {S}tatistical {P}hysics",
  editor    =   "G. H. Weiss",
  publisher =   "SIAM, Philadelphia",
  year      =   "1994"}

@article{best,
    author  =   "Westbury, Bruce W.",
     title  =   "{$R$}-matrices and the magic square",
   journal  =   "J. Phys. A",
  fjournal  =   "Journal of Physics A: Mathematical and General",
    volume  =   "36",
      year  =   "2003",
    number  =   "7",
     pages  =   "1947--1959",
      issn  =   "0305-4470",
     coden  =   "JPHAC5",
   mrclass  =   "17B10",
  mrnumber  =   "1 960 703",
      note = "\url{https://doi.org/10.1088/0305-4470/36/11/501}"}

@article{pier,
    author  =   "Deligne, Pierre X. and Gross, Benedict H.",
     title  =   "On the exceptional series, and its descendants",
   journal  =   "C. R. Math. Acad. Sci. Paris",
  fjournal  =   "Comptes Rendus Math\'ematique. Acad\'emie des Sciences. Paris",
    volume  =   "335",
      year  =   "2002",
    number  =   "11",
     pages  =   "877--881",
      issn  =   "1631-073X",
   mrclass  =   "20Gxx",
  mrnumber  =   "1 952 563",
note = "\url{https://doi.org/10.1016/S1631-073X(02)02590-6}"}

@article{jame,
    author  =   "Landsberg, James. M. and Manivel, L.",
     title  =   "Triality, exceptional {L}ie algebras and {D}eligne dimension formulas",
   journal  =   "Adv. Math.",
  fjournal  =   "Advances in Mathematics",
    volume  =   "171",
      year  =   "2002",
    number  =   "1",
     pages  =   "59--85",
      issn  =   "0001-8708",
     coden  =   "ADMTA4",
   mrclass  =   "17B20 (17B25)",
  mrnumber  =   "1 933 384",
mrreviewer  =   "Dmitri I. Panyushev",
note  =   "\url{https://doi.org/10.1006/aima.2002.2071}"}

@techreport{hobby1992,
     author =   "John D. Hobby",
      title =   "{A User's Manual for MetaPost}",
       year =   "1992",
      month =   "apr",
   language =   "english",
institution =   "AT\&T Bell Laboratories",
    address =   "Murray Hill, New Jersey",
       date =   "April 1992",
     number =   "162",
     npages =   "ii+88~pages"}

@techreport{CSTR116,
     author =   "Kernighan, Brian W.",
      title =   "{PIC}---{A} Graphics Language for Typesetting",
       type =   "Computing Science Tech. Rep.",
     number =   "116",
institution =   "AT\&T Bell Laboratories",
    address =   "Murray Hill, New Jersey",
       year =   "1984"}

@unpublished{VoQS,
  author    =   "Ball, Martin J. and Esling, John and Dickson, Craig",
  title     =   "{VoQS: Voice Quality Symbols}",
  note      =   "Revised to 1994",
  year      =   "1994"}

@phdthesis{Brown:1988:IEL,
  author    =   "Marcus E. Brown",
  title     =   "An Interactive Environment for Literate Programming",
  school    =   "Texas A\&M University",
  address   =   "TX, USA",
  pages     =   "ix + 102",
  month     =   "aug",
  year      =   "1988"}

@inbook{inbook,
  author    =   "D. W. Baker and N. L. Carter",
  year      =   "1972",
  editor    =   "H. C. Heard and I. Y. Borg and N. L. Carter and C. B. Raleigh",
  title     =   "Seismic {V}elocity {A}nisotropy {C}alculated for {U}ltramafic {M}inerals
                and {A}ggregates",
  booktitle =   "Flow and {F}racture of {R}ocks",
  publisher =   "Am. Geophys. Union",
  series    =   "Geophysical Monograph",
  volume    =   "16",
  pages     =   "157--166",
note  =   "\url{https://doi.org/10.1029/GM016p0157}"}

@mastersthesis{segms,
  author    =   "G[unter] S[ergei] Lodha",
  title     =   "Quantitative interpretation of airborne
                electromagnetic response for a spherical model",
  school    =   "University of Toronto",
  year      =   "1974"}

@incollection{Jones:Phoneme,
  author    =   "Jones, Daniel",
  title     =   "{The term `phoneme'}",
  editor    =   "Jones, W. E. and Laver, J.",
  booktitle =   "Phonetics in Linguistics: A Book of Reading",
  publisher =   "Longman",
  address   =   "London",
  pages     =   "187--204",
  year      =   "1973"}

@booklet{URW:kerning,
  author       = "Bill Murrey",
  title        = "Kerning on the Fly",
  howpublished = "URW Non-Plus-Ultra Typography series",
  address      = "Pittsburg",
  year         = "1991"}

@misc{netpbm,
  author    =   "Bill Davidsen",
  title     =   "{NETPBM}",
  year      =   "1993",
  note      =   "ftp://ftp.wustl.edu/graphics/graphics/packages/ {NetPBM}"}

% WSPC JAMS BibTeX Style File -- version 1.0
% BibTeX version 0.99c, intended for LaTeX2e
%
% 2004/06/16  Rajesh <[email protected]>
%
% This style was made from 'abbrv.bst' with lots of tweaking to make
% it look like JAMS.
%
% If you make bug fixes, improvements, etc. please send in yours
% comments and suggetions to Rajesh <[email protected]>
%
% The style followed is inhouse BiB pattern 2
%
% Copyright (C) 2004, all rights reserved.
% Copying of this file is authorized only if either
% (1) you make absolutely no changes to your copy, including name, or
% (2) if you do make changes, you name it something other than
% btxbst.doc, plain.bst, unsrt.bst, alpha.bst, abbrv.bst and ws-JAMS.bst.
% This restriction helps ensure that all standard styles are identical.
% The file btxbst.doc has the documentation for this style.

ENTRY
  { address
    author
    booktitle
    chapter
    edition
    editor
    howpublished
    institution
    journal
    key
    month
    note
    number
    organization
    pages
    publisher
    school
    series
    title
    type
    volume
    year
    url
  }
  {}
  { label }

INTEGERS { output.state before.all mid.sentence after.quote after.sentence
        after.quoted.block after.block }

FUNCTION {init.state.consts}
{ #0 'before.all :=
  #1 'mid.sentence :=
  #2 'after.quote :=
  #3 'after.sentence :=
  #4 'after.quoted.block :=
  #5 'after.block :=
}

FUNCTION {disp.msg.screen} { #1 }

FUNCTION {type.msg}
{ disp.msg.screen
     { "<ws-JAMS.bst>"
       top$
       "World Scientific's Bibliography Style File for JAMS"
       top$
       "version 1.0 (26-3-2004)"
       top$
       "-- by Rajesh"
       top$
       "<Sorted version, follows inhouse bib-pattern 2>"
       top$
     }
     { skip$ }
   if$
}

STRINGS { s t }

FUNCTION {output.nonnull}
{ 's :=
  output.state mid.sentence =
    { ", " * write$ }
    { output.state after.quote =
    { " " * write$ }
    { output.state after.block =
        { add.period$ write$
          newline$
          "\newblock " write$
        }
        { output.state before.all =
        'write$
        { output.state after.quoted.block =
            { write$
              newline$
              "\newblock " write$
            }
            { add.period$ " " * write$ }
          if$
        }
          if$
        }
      if$
    }
      if$
      mid.sentence 'output.state :=
    }
  if$
  s
}

FUNCTION {output}
{ duplicate$ empty$
    'pop$
    'output.nonnull
  if$
}

FUNCTION {output.check}
{ 't :=
  duplicate$ empty$
    { pop$ "empty " t * " in " * cite$ * warning$ }
    'output.nonnull
  if$
}

FUNCTION {output.bibitem}
{ newline$
  "\bibitem{" write$
  cite$ write$
  "}" write$
  newline$
  ""
  before.all 'output.state :=
}

FUNCTION {blank.sep}
{
 after.quote 'output.state :=
}

FUNCTION {fin.entry}
{ output.state after.quoted.block =
    'skip$
    'add.period$
  if$
  write$
  newline$
}

FUNCTION {new.block}
{ output.state before.all =
    'skip$
    { output.state after.quote =
    { after.quoted.block 'output.state := }
    { after.block 'output.state := }
      if$
    }
  if$
}

FUNCTION {new.sentence}
{ output.state after.block =
    'skip$
    { output.state before.all =
    'skip$
    { after.sentence 'output.state := }
      if$
    }
  if$
}

FUNCTION {not}
{   { #0 }
    { #1 }
  if$
}

FUNCTION {and}
{   'skip$
    { pop$ #0 }
  if$
}

FUNCTION {or}
{   { pop$ #1 }
    'skip$
  if$
}

FUNCTION {new.block.checka}
{ empty$
    'skip$
    'new.block
  if$
}

FUNCTION {new.block.checkb}
{ empty$
  swap$ empty$
  and
    'skip$
    'new.block
  if$
}

FUNCTION {new.sentence.checka}
{ empty$
    'skip$
    'new.sentence
  if$
}

FUNCTION {field.or.null}
{ duplicate$ empty$
    { pop$ "" }
    'skip$
  if$
}

FUNCTION {emphasize}
{ duplicate$ empty$
    { pop$ "" }
    { "{\em " swap$ * "}" * }
  if$
}

FUNCTION {bold}
{ duplicate$ empty$
    { pop$ "" }
    { "{\bf " swap$ * "}" * }
  if$
}

INTEGERS { nameptr namesleft numnames }

FUNCTION {format.names}
{ 's :=
  #1 'nameptr :=
  s num.names$ 'numnames :=
  numnames 'namesleft :=
    { namesleft #0 > }
    { s nameptr "{f.~}{vv~}{ll}{, jj}" format.name$ 't :=
      nameptr #1 >
    { namesleft #1 >
        { ", " * t * }
        { numnames #2 >
        { "" * }
        'skip$
          if$
          t "others" =
        { " {\em et~al.}" * }
        { " and " * t * }
          if$
        }
      if$
    }
    't
      if$
      nameptr #1 + 'nameptr :=
      namesleft #1 - 'namesleft :=
    }
  while$
}

FUNCTION {format.authors}
{ author empty$
    { "" }
    { author format.names }
  if$
}

FUNCTION {format.editors}
{ editor empty$
    { "" }
    { editor format.names
      editor num.names$ #1 >
    { " (eds.)" * }
    { " (ed.)" * }
      if$
    }
  if$
}

FUNCTION {format.eeditors}
{ editor empty$
    { "" }
    { editor num.names$ #1 >
    { " eds." * }
    { " ed." * }
      if$
    editor format.names}
  if$
}

FUNCTION {format.title}
{ title empty$
    { "" }
    { "" title "t" change.case$ * "" * }
  if$
}

FUNCTION {format.title.p}
{ title empty$
    { "" }
    { "" title "t" change.case$ * "" * }
  if$
}

FUNCTION {n.dashify}
{ 't :=
  ""
    { t empty$ not }
    { t #1 #1 substring$ "-" =
    { t #1 #2 substring$ "--" = not
        { "--" *
          t #2 global.max$ substring$ 't :=
        }
        {   { t #1 #1 substring$ "-" = }
        { "-" *
          t #2 global.max$ substring$ 't :=
        }
          while$
        }
      if$
    }
    { t #1 #1 substring$ *
      t #2 global.max$ substring$ 't :=
    }
      if$
    }
  while$
}

FUNCTION {format.mdate}
{ year empty$
    { month empty$
    { "" }
    { "there's a month but no year in " cite$ * warning$
      month
    }
      if$
    }
    { month empty$
    { " (" year * ")" *}
    { " (" * month * "" year * ")" *}
      if$
    }
  if$
}


FUNCTION {format.date}
{ year empty$
    { month empty$
    { "" }
    { "there's a month but no year in " cite$ * warning$
      month
    }
      if$
    }
    { month empty$
    { " (" year * ")" *}
    { " (" * month * "" year * ")" *}
      if$
    }
  if$
}

FUNCTION {format.btitle}
    { title emphasize }

FUNCTION {tie.or.space.connect}
{ duplicate$ text.length$ #3 <
    { "~" }
    { " " }
  if$
  swap$ * *
}

FUNCTION {empty.field.to.null.string}
{ duplicate$ empty$
    { pop$ "" }
    { skip$ }
  if$
}

FUNCTION {either.or.check}
{ empty$
    'pop$
    { "can't use both " swap$ * " fields in " * cite$ * warning$ }
  if$
}

FUNCTION {format.bvolume}
{ series empty$
   { "" }
    { volume empty$
       {series *}
       {", " * series * "," * "Vol.~" volume *}
      if$
    }
  if$
}

FUNCTION {format.number.series}
{ volume empty$
    { number empty$
    { series field.or.null }
    { output.state mid.sentence =
        { "no.~" }
        { "No.~" }
      if$
      number *
      series empty$
        { "there's a number but no series in " cite$ * warning$ }
        { " in " * series * }
      if$
    }
      if$
    }
    { "" }
  if$
}

FUNCTION {format.edition}
{ edition empty$
    { "" }
    { output.state mid.sentence =
    { edition "l" change.case$ " edn." * }
    { edition "t" change.case$ " edn." * }
      if$
    }
  if$
}

INTEGERS { multiresult }

FUNCTION {multi.page.check}
{ 't :=
  #0 'multiresult :=
    { multiresult not
      t empty$ not
      and
    }
    { t #1 #1 substring$
      duplicate$ "-" =
      swap$ duplicate$ "," =
      swap$ "+" =
      or or
    { #1 'multiresult := }
    { t #2 global.max$ substring$ 't := }
      if$
    }
  while$
  multiresult
}

FUNCTION {first.page.number}
{ 't :=
  ""
    { t "" =
        { #0 }
        { t #1 #1 substring$ "-" = not }
      if$
    }
    { t #1 #1 substring$ *
      t #2 global.max$ substring$ 't :=
    }
  while$
}

FUNCTION {format.pages}
{ pages empty$
    { "" }
    { pages multi.page.check
        { "" pages n.dashify tie.or.space.connect }
        { "p." pages tie.or.space.connect }
      if$
    }
  if$
}

FUNCTION {format.ppages}
{ pages empty$
    { "" }
    { pages multi.page.check
        { "pp." pages n.dashify tie.or.space.connect }
        { "p." pages tie.or.space.connect }
      if$
    }
  if$
}

FUNCTION {format.number}
{ number empty$
    { "" }
    { "("  number * ")" *}
  if$
}

FUNCTION {format.journal.volume.number}
{ journal empty$
    { "empty " t * " in " * cite$ * warning$ ""}
    { journal emphasize }
  if$
  volume empty$      %% warning if no volume
    { "empty volume in " cite$ * warning$ " " *}
    { " " * volume bold *}      %% make volume bold
%%    { "vol.~" volume * }
  if$
  month empty$
    { format.number *}
    'skip$
  if$
}

FUNCTION {format.series.volume.number}
{ series empty$
%%    { "empty " t * " in " * cite$ * warning$ ""}
    { "" }                  
    { series emphasize }
  if$
  volume empty$ 
    { "" *}                 
    { " " * volume bold *}  
%%    { "vol.~" volume * }
  if$
  month empty$
    { format.number *}
    'skip$
  if$
}

% following not used
FUNCTION {format.volume}
{ volume empty$
    { "" }
    { volume bold }            
%%    { "vol.~" volume * }
  if$
}

FUNCTION {format.chapter.pages}
{ chapter empty$
    'format.ppages
    { type empty$
    { "ch.~" chapter * }
    { type "l" change.case$ chapter tie.or.space.connect }
      if$
      pages empty$
    'skip$
    { ", " * format.ppages * }
      if$
    }
  if$
}

FUNCTION {format.chapter.ppages}
{ chapter empty$
    'format.ppages
    { type empty$
    { "ch.~" chapter * }
    { type "l" change.case$ chapter tie.or.space.connect }
      if$
      pages empty$
    'skip$
    { ", " * format.ppages * }
      if$
    }
  if$
}

FUNCTION {format.in.ed.sbooktitle}
{ booktitle empty$
    { "" }
    { ", {\em " * booktitle * "\/}, " *
       format.eeditors
    }
  if$
}

FUNCTION {format.in.ed.inbooktitle}
{ booktitle empty$
    { "" }
    { ", {\em " * booktitle * "\/}" *
       format.eeditors
    }
  if$
}


FUNCTION {format.in.ed.booktitle}
{ booktitle empty$
    { "" }
    { ", {\em " * booktitle * "\/}, " *
       format.eeditors
    }
  if$
}

FUNCTION {format.thesis.type}
{ type empty$
    'skip$
    { pop$
      output.state after.block =
    { type "t" change.case$ }
    { type "l" change.case$ }
      if$
    }
  if$
}

FUNCTION {empty.misc.check}
{ author empty$ title empty$ howpublished empty$ 
  month empty$ year empty$ note empty$
  and and and and and
    { "all relevant fields are empty in " cite$ * warning$ }
    'skip$
  if$
}

FUNCTION {format.tr.number}
{ type empty$
    { "Tech. Report" }
    'type
  if$
  number empty$
    { "l" change.case$ }
    { number tie.or.space.connect }
  if$
}


FUNCTION {format.paddress}
{ address empty$
    { "" }
    { "(" address * ")" * }
  if$
}

FUNCTION {format.article.crossref}
{ key empty$
    { journal empty$
    { "need key or journal for " cite$ * " to crossref " * crossref *
      warning$
      ""
    }
    { " in {\em " journal * "\/}" * }
      if$
    }
    { " in " key * }
  if$
  "\cite{" * crossref * "}" *
}

FUNCTION {format.crossref.editor}
{ editor #1 "{vv~}{ll}" format.name$
  editor num.names$ duplicate$
  #2 >
    { pop$ " {\em et~al.}" * }
    { #2 <
    'skip$
    { editor #2 "{ff }{vv }{ll}{ jj}" format.name$ "others" =
        { " {\em et~al.}" * }
        { " and " * editor #2 "{vv~}{ll}" format.name$ * }
      if$
    }
      if$
    }
  if$
}

FUNCTION {format.book.crossref}
{ volume empty$
    { "empty volume in " cite$ * "'s crossref of " * crossref * warning$
      "In "
    }
    { "Vol.~" volume *
      " of " *
    }
  if$
  editor empty$
  editor field.or.null author field.or.null =
  or
    { key empty$
    { series empty$
        { "need editor, key, or series for " cite$ * " to crossref " *
          crossref * warning$
          "" *
        }
        { "{\em " * series * "\/}" * }
      if$
    }
    { key * }
      if$
    }
    { format.crossref.editor * }
  if$
  "\cite{" * crossref * "}" *
}

FUNCTION {format.incoll.inproc.crossref}
{ editor empty$
  editor field.or.null author field.or.null =
  or
    { key empty$
    { booktitle empty$
        { "need editor, key, or booktitle for " cite$ * " to crossref " *
          crossref * warning$
          ""
        }
        { " in {\em " booktitle * "\/}" * }   
      if$
    }
    { " in " key * }
      if$
    }
    { " in " format.crossref.editor * }   
  if$
  "\cite{" * crossref * "}" *
}

FUNCTION {push.url}
{}

FUNCTION {push.date}
% format: month year
{ year empty$
    { month empty$
        { "" }
        { "there's a month but no year in " cite$ * warning$
          month
        }
      if$
    }
    { month empty$
        { year }
        { month " " * year * }
      if$
    }
  if$
}


FUNCTION {format.address.date}
{ address empty$
    {"address is missing " cite$ * warning$
    year empty$ 
        { "" }
        { push.date *} 
        if$
    }
    { "(" address * ", " * year * ")" * }
  if$
}

FUNCTION {format.school.date}
{ school empty$
    {"school is missing " cite$ * warning$
    year empty$ 
        { "" }
        { push.date *} 
        if$
    }
    { "(" school * ", " * year * ")" * }
  if$
}

FUNCTION {push.address.publisher.year}
% the whole imprint
{ address empty$
    { publisher empty$
        { url empty$
            { year empty$ 
                { "" }
                { push.date } 
              if$
            }
            { 
              push.url
              year empty$
                { skip$ }
                { ", " * push.date * ")" * }
              if$
            }
          if$
        }
      { "(" publisher *
      year empty$
            { skip$ }
            { ", " * push.date * ")" * }
          if$
        }
      if$
    }
    { 
      publisher empty$
        { skip$ }
        { "(" publisher * ", " * address * }
      if$
      year empty$
    { ")" * }
    { ", " * push.date * ")" * }
      if$
    }
  if$
}

FUNCTION {article}
{ output.bibitem
  format.authors "author" output.check
  format.title "title" output.check
  crossref missing$
    { format.journal.volume.number output
      blank.sep
      format.date "year" output.check
      blank.sep
      format.pages output
    }
    { format.article.crossref output.nonnull
      format.pages output
    }
  if$
  note output
  fin.entry
}

FUNCTION {book}
{ output.bibitem
  author empty$
    { format.editors "author and editor" output.check }
    { format.authors output.nonnull
      crossref missing$
    { "author and editor" editor either.or.check }
    'skip$
      if$
    }
  if$
  format.btitle "title" output.check
  crossref missing$
    { format.bvolume output
      format.number.series output
      format.edition output
      blank.sep
      push.address.publisher.year "publisher" output.check
    }
    { new.block
      format.book.crossref output.nonnull
    }
  if$
  new.block
  note output
  fin.entry
}

FUNCTION {booklet}
{ output.bibitem
  format.authors output
  title empty$
    { "empty title in " cite$ * warning$
      howpublished new.sentence.checka
    }
    { howpublished empty$ not
      address empty$ month empty$ year empty$ and and
      or
    { format.title.p output.nonnull }
    { format.title output.nonnull }
      if$
    }
  if$
  howpublished output
  address output
  blank.sep
  format.date output
  new.block
  note output
  fin.entry
}

FUNCTION {inbook}
{ output.bibitem
  author empty$
    { format.editors "author and editor" output.check }
    { format.authors output.nonnull}
  if$
  format.btitle "title" output.check
  blank.sep
  format.in.ed.inbooktitle output  %remove check for booktitle
  blank.sep
  crossref missing$
    { format.bvolume output
      blank.sep
      format.number.series output
      push.address.publisher.year "publisher" output.check
      address output
      format.chapter.ppages "chapter and pages" output.check      
    }
    { format.chapter.ppages "chapter and pages" output.check
      new.block
      format.book.crossref output.nonnull
    }
  if$
  format.edition output
  note output
  fin.entry
}

FUNCTION {incollection}
{ output.bibitem
  format.authors "author" output.check
  format.title "title" output.check
  blank.sep
  crossref missing$
    { format.in.ed.booktitle "booktitle or editor" output.check
     format.series.volume.number output
      blank.sep
      push.address.publisher.year "publisher" output.check
      format.ppages output
      format.edition output
    }
    { format.incoll.inproc.crossref output.nonnull
      format.ppages output
    }
  if$
  new.block
  note output
  fin.entry
}

FUNCTION {inproceedings}
{ output.bibitem
  format.authors "author" output.check
  format.title "title" output.check
  blank.sep
  format.in.ed.sbooktitle output  %remove check for booktitle
  blank.sep
      journal empty$
         {format.series.volume.number output}
         {format.journal.volume.number output}
     if$
      organization output
  publisher empty$
  {format.address.date output}
  {push.address.publisher.year "publihser" output.check}
  if$
      format.ppages output
  new.block
  fin.entry
}

FUNCTION {conference} { inproceedings }

FUNCTION {manual}
{ output.bibitem
  author empty$
    { organization empty$
    'skip$
    { organization output.nonnull
      address output
    }
      if$
    }
    { format.authors output.nonnull }
  if$
  format.btitle "title" output.check
  author empty$
    { organization empty$
    { address new.block.checka
      address output
    }
    'skip$
      if$
    }
    { organization address new.block.checkb
      organization output
      address output
    }
  if$
  format.edition output
  format.date output
  new.block
  note output
  fin.entry
}

FUNCTION {mastersthesis}
{ output.bibitem
  format.authors "author" output.check
  format.title "title" output.check
  "Master's thesis" format.thesis.type output.nonnull
  %format.school.date "school" output.check
  school output
  blank.sep
  format.date output
  new.block
  note output
  fin.entry
}

FUNCTION {misc}
{ output.bibitem
  format.authors output
  title empty$
    { howpublished new.sentence.checka }
    { howpublished empty$ not
      month empty$ year empty$ and
      or
    { format.title.p output.nonnull }
    { format.title output.nonnull }
      if$
      blank.sep
    }
  if$
  howpublished output
  format.date output
  note output
  fin.entry
  empty.misc.check
}

FUNCTION {phdthesis}
{ output.bibitem
  format.authors "author" output.check
  format.title "title" output.check
  "PhD thesis" format.thesis.type output.nonnull
  school "school" output.check
  blank.sep
  format.date "year" output.check
  format.ppages output
  new.block
  note output
  fin.entry
}

FUNCTION {proceedings}
{ output.bibitem
  editor empty$
    { organization output }
    { format.editors output.nonnull }
  if$
  format.btitle "title" output.check
  blank.sep  
  format.series.volume.number output   
  editor empty$
    'skip$
    { organization output }
  if$
   push.address.publisher.year "publisher" output.check
  new.block
  note output
  fin.entry
}

FUNCTION {techreport}
{ output.bibitem
  format.authors "author" output.check
  format.title "title" output.check
  format.tr.number output.nonnull
  institution "institution" output.check
  address output
  blank.sep
  format.date "year" output.check
  new.block
  note output
  fin.entry
}

FUNCTION {unpublished}
{ output.bibitem
  format.authors "author" output.check
  format.title.p "title" output.check
  note "note" output.check
  blank.sep
  format.date output
  fin.entry
}

FUNCTION {default.type} { misc }

MACRO {jan} {"January"}

MACRO {feb} {"February"}

MACRO {mar} {"March"}

MACRO {apr} {"April"}

MACRO {may} {"May"}

MACRO {jun} {"June"}

MACRO {jul} {"July"}

MACRO {aug} {"August"}

MACRO {sep} {"September"}

MACRO {oct} {"October"}

MACRO {nov} {"November"}

MACRO {dec} {"December"}

MACRO {acmcs} {"ACM Computing Surveys"}

MACRO {acta} {"Acta Informatica"}

MACRO {cacm} {"Communications ACM"}

MACRO {ibmjrd} {"IBM J. Research and Development"}

MACRO {ibmsj} {"IBM Systems~J."}

MACRO {ieeese} {"IEEE Trans. Software Engineering"}

MACRO {ieeetc} {"IEEE Trans. Computers"}

MACRO {ieeetcad} {"IEEE Trans. Computer-Aided Design"}

MACRO {ipl} {"Information Processing Letters"}

MACRO {jacm} {"J.~ACM"}

MACRO {jcss} {"J.~Computer and System Sciences"}

MACRO {scp} {"Science of Computer Programming"}

MACRO {sicomp} {"SIAM J. Computing"}

MACRO {tocs} {"ACM Trans. Computer Systems"}

MACRO {tods} {"ACM Trans. Database Systems"}

MACRO {tog} {"ACM Trans. Graphics"}

MACRO {toms} {"ACM Trans. Mathematical Software"}

MACRO {toois} {"ACM Trans. Office Information Systems"}

MACRO {toplas} {"ACM Trans. Programming Languages and Systems"}

MACRO {tcs} {"Theoretical Computer Science"}

READ

EXECUTE {type.msg}

FUNCTION {sortify}
{ purify$
  "l" change.case$
}

INTEGERS { len }

FUNCTION {chop.word}
{ 's :=
  'len :=
  s #1 len substring$ =
    { s len #1 + global.max$ substring$ }
    { s }
  if$
}

FUNCTION {sort.format.names}
{ 's :=
  #1 'nameptr :=
  ""
  s num.names$ 'numnames :=
  numnames 'namesleft :=
    { namesleft #0 > }
    { nameptr #1 >
        { "   " * }
        { skip$ }
      if$
      s nameptr "{vv{ } }{ll{ }}{  ff{ }}{  jj{ }}" format.name$ 't :=
      nameptr numnames = t "others" = and
        { "et al" * }
        { t sortify * }
      if$
      nameptr #1 + 'nameptr :=
      namesleft #1 - 'namesleft :=
    }
  while$
}

FUNCTION {sort.format.title}
{ 't :=
  "A " #2
    "An " #3
      "The " #4 t chop.word
    chop.word
  chop.word
  sortify
  #1 global.max$ substring$
}

FUNCTION {author.sort}
{ author empty$
    { key empty$
        { "to sort, need author or key in " cite$ * warning$ "" }
        { key sortify }
      if$
    }
    { author sort.format.names }
  if$
}

FUNCTION {author.editor.sort}
{ author empty$
    { editor empty$
        { key empty$
            { "to sort, need author, editor, or key in " cite$ * warning$ "" }
            { key sortify }
          if$
        }
        { editor sort.format.names }
      if$
    }
    { author sort.format.names }
  if$
}

FUNCTION {author.organization.sort}
{ author empty$
    { organization empty$
        { key empty$
            { "to sort, need author, organization, or key in " cite$ * warning$ "" }
            { key sortify }
          if$
        }
        { "The " #4 organization chop.word sortify }
      if$
    }
    { author sort.format.names }
  if$
}

FUNCTION {editor.organization.sort}
{ editor empty$
    { organization empty$
        { key empty$
            { "to sort, need editor, organization, or key in " cite$ * warning$ "" }
            { key sortify }
          if$
        }
        { "The " #4 organization chop.word sortify }
      if$
    }
    { editor sort.format.names }
  if$
}

FUNCTION {author.organization.institution.sort}
{ author empty$
    { organization empty$
        { institution empty$
            { key empty$
                { "to sort, need author, organization, institution or key in " cite$ * warning$ "" }
                { key sortify }
              if$
            }
            { "The " #4 institution chop.word sortify }
          if$
        }
        { "The " #4 organization chop.word sortify }
      if$
    }
    { author sort.format.names }
  if$
}


FUNCTION {presort}
{ type$ "ieeetranbstctl" =
    { key empty$
        { "_" }
        { key sortify }
      if$
    }
    { type$ "book" =
      type$ "inbook" =
      or 
        { author.editor.sort }
        { type$ "proceedings" =
          type$ "periodical" =
          or
            { editor.organization.sort }
            { type$ "manual" =
              type$ "electronic" =
              type$ "misc" =
              or or
                { author.organization.sort }
                { type$ "standard" =
                   { author.organization.institution.sort }
                   { author.sort }
                 if$ 
                }
              if$
            }
          if$
        }
      if$
      "    "
      *
      year empty.field.to.null.string sortify
      *
      "    "
      *
      title empty.field.to.null.string
      sort.format.title
      *
    }
  if$
  #1 entry.max$ substring$
  'sort.key$ :=
}

ITERATE {presort}

SORT

STRINGS { longest.label }

INTEGERS { number.label longest.label.width }

FUNCTION {initialize.longest.label}
{ "" 'longest.label :=
  #1 'number.label :=
  #0 'longest.label.width :=
}

FUNCTION {longest.label.pass}
{ number.label int.to.str$ 'label :=
  number.label #1 + 'number.label :=
  label width$ longest.label.width >
    { label 'longest.label :=
      label width$ 'longest.label.width :=
    }
    'skip$
  if$
}

EXECUTE {initialize.longest.label}

ITERATE {longest.label.pass}

FUNCTION {begin.bib}
{ preamble$ empty$
    'skip$
    { preamble$ write$ newline$ }
  if$
  "\begin{thebibliography}{"  longest.label  * "}" * write$ newline$
}

EXECUTE {begin.bib}

EXECUTE {init.state.consts}

ITERATE {call.type$}

FUNCTION {end.bib}
{ newline$
  "\end{thebibliography}" write$ newline$
}

EXECUTE {end.bib}

%%
%% End of file
%% For Support: [email protected], [email protected]
%% ws-JAMS.bst (C) World Scientific Publishing Co.

39 KB — too long to show here. It arrives with the project.

%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
%% Text Area: 8in (include Runningheads) x 5in
%% ws-jams.tex  :  15-05-2026
%% Class file to use with ws-jams.cls written in LaTeX2e.
%% The content, structure, format and layout of this style file is the
%% property of World Scientific Publishing Co. Pte. Ltd.
%% Copyright 2026 by World Scientific Publishing Co.
%% All rights are reserved.
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

\documentclass{ws-jams}
%\documentclass[wsdraft]{ws-jams}

\usepackage[super]{cite}
\usepackage{xcolor}
\usepackage[verbose,hypertexnames=false]{hyperref}
\hypersetup{colorlinks=false,allbordercolors=blue,pdfborderstyle={/S/U/W 1}}
% \label, \ref and \cite commands are highly recommended


\begin{document}

\markboth{Authors' Names}
{Instructions for Typing Manuscripts (Paper's Title)}

%%%%%%%%%%%%%%%%%%%%% Publisher's Area please ignore %%%%%%%%%%%%%%%
%
\catchline{}{}{}{}{}
%
%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%

\title{Your paper}

\author{First Author\footnote{Typeset names in 8 pt Roman. Use the footnote to
indicate the present or permanent address of the author.}}

\address{University Department, University Name, Address\\
City, State ZIP/Zone,
Country\footnote{State completely without abbreviations, the
affiliation and mailing address, including country. Typeset in 8 pt
italic.}
}

\author{Second Author}

\address{Group, Laboratory, Address\\
City, State ZIP/Zone, Country
}

\maketitle

\begin{history}
\received{(Day Month Year)}
\accepted{(Day Month Year)}
\published{(Day Month Year)}
%\comby{(Handling Editor)}
\end{history}

\begin{abstract}
The abstract should summarize the context, content
and conclusions of the paper in less than 200 words. It should
not contain any references or displayed equations. Typeset the
abstract in 8 pt roman with baselineskip of 10 pt, making
an indentation of 1.5 pica on the left and right margins.
\end{abstract}

\keywords{Keyword1; keyword2; keyword3.}

\section{General Appearance}	
Contributions to the {\it Journal of Advanced Manufacturing Systems} will mostly be processed by using the authors' source files. These should
be submitted with the manuscripts, and resubmitted in the final form
if a paper requires revision before being accepted for publication.

\section{The Main Text}
Authors are encouraged to have their contribution checked for grammar.
American spelling should be used. Abbreviations are allowed but should
be spelled out in full when first used. Integers ten and below are to be
spelled out. Italicize foreign language phrases (e.g.~Latin, French).

The text is to be typeset in 10~pt Times roman, single spaced with
baselineskip of 13~pt. Text area (excluding running title) is
7.7 inches high and 5 inches wide.  Final pagination and
insertion of running titles will be done by the publisher.

\section{Running Heads}
Please provide a shortened runninghead (not more than eight words) for
the title of your paper. This will appear on the top right-hand side
of your paper.

\section{Major Headings}
Major headings should be typeset in boldface with the first
letter of important words capitalized.

\subsection{Sub-headings}
Sub-headings should be typeset in boldface italic and capitalize
the first letter of the first word only. Section number to be in
boldface roman.

\subsubsection{Sub-subheadings}
Typeset sub-subheadings in medium face italic and capitalize the
first letter of the first word only. Section numbers to be in
roman.

\subsection{Numbering and spacing}
Sections, sub-sections and sub-subsections are numbered in
Arabic.  Use double spacing before all section headings, and
single spacing after section headings. Flush left all paragraphs
that follow after section headings.

\subsection{Lists of items}
Lists may be laid out with each item marked by a bullet:
\begin{itemlist}
 \item item one,
 \item item two.
\end{itemlist}
Items may also be numbered in lowercase roman numerals:
\begin{romanlist}[(ii)]
\item item one
\item item two
\begin{romanlist}[(b)]
\item Lists within lists can be numbered with lowercase roman letters,
\item second item.
\end{romanlist}
\end{romanlist}

\section{Equations}
Displayed equations should be numbered consecutively in each
section, with the number set flush right and enclosed in
parentheses

\renewcommand{\theequation}{\thesection.\arabic{equation}}
\setcounter{equation}{0}
\begin{equation}
\mu(n, t) = {\sum^\infty_{i=1} 1(d_i < t, N(d_i) = n) \over
\int^t_{\sigma=0} 1(N(\sigma) = n)d\sigma}\,.
\label{diseqn}
\end{equation}

Equations should be referred to in abbreviated form,
e.g.~``Eq.~(\ref{diseqn})'' or ``(\ref{diseqn})''. In multiple-line
equations, the number should be given on the last line.

Displayed equations are to be centered on the page width.
Standard English letters like x are to appear as $x$
(italicized) in the text if they are used as mathematical
symbols. Punctuation marks are used at the end of equations as
if they appeared directly in the text.

For multiline equations, prefer using \verb|align| or \verb|align*| instead of \verb|eqnarray|.
\begin{align}
g(x) & = \sum_{k=1}^{N} y_k g(x_k) \nonumber\\
& = \sum_{k=1}^{N} y_k \sum_{l=1}^{M} b_{kl} w_l \nonumber\\
& = \sum_{k=1}^{N} \sum_{l=1}^{M} b_{kl} y_k w_l
\end{align}

\section{Theorem Environments}

\begin{theorem}\label{thm1}
Theorems, lemmas, etc. are to be numbered
consecutively in the paper. Use double spacing before and after
theorems, lemmas, etc.
\end{theorem}

\begin{proof}
Proofs should end with a box.
\end{proof}

\section{Illustrations and Photographs}
Figures are to be inserted in the text nearest their first reference. If the author requires the publisher to reduce the figures, ensure that the figures (including letterings and numbers) are large enough to be clearly seen after reduction. If photo\-graphs are to be used, only black and white ones are acceptable.

\begin{figure}[th]
\centerline{\includegraphics[width=4.6cm]{jamsf1}}
\vspace*{8pt}
\caption{A schematic illustration of dissociative recombination. The
direct mechanism, 4m$^2_\pi$ is initiated when the molecular ion S$_{\rm L}$ captures an electron with kinetic energy.}
\label{fig1}
\alttext{Description of the figure}
\end{figure}

Figures are to be placed either top or bottom and
sequentially numbered in Arabic numerals. The
caption must be placed below the figure. Typeset in 8 pt
roman with baselineskip of 10~pt. Use double spacing between a
caption and the text that follows immediately.

Previously published material must be accompanied by written
permission from the author and publisher.

\section{Tables}
Tables should be inserted in the text as close to the point of
reference as possible. Some space should be left above and below
the table.

Tables should be numbered sequentially in the text in Arabic
numerals. Captions are to be centralized above the tables.
Typeset tables and captions in 8 pt roman with baselineskip of 10 pt.

\begin{table}[ph]
\vspace{-5pt}
\tbl{Comparison of acoustic for frequencies for piston-cylinder problem.}
{\begin{tabular}{@{}cccc@{}}
\toprule
Piston mass & Analytical frequency & TRIA6-$S_1$ model &\% Error \\
& (Rad/s) & (Rad/s) \\
\colrule
1.0\hphantom{00} & \hphantom{0}281.0 & \hphantom{0}280.81 & 0.07 \\
0.1\hphantom{00} & \hphantom{0}876.0 & \hphantom{0}875.74 & 0.03 \\
0.01\hphantom{0} & 2441.0 & 2441.0\hphantom{0} & 0.0\hphantom{0} \\
0.001 & 4130.0 & 4129.3\hphantom{0} & 0.16\\
\botrule
\end{tabular}}
\end{table}

If tables need to extend over to a second page, the continuation
of the table should be preceded by a caption,
e.g.~``{\it Table 2.} $(${\it Continued}$)$''

\section{Footnotes}
Footnotes should be numbered sequentially in superscript
lowercase roman letters.\footnote{Footnotes should be
typeset in 8 pt roman at the bottom of the page.}

\section*{Acknowledgements}
This section should come before the References. Dedications and funding
information may also be included here.

\section*{ORCID}
You are encouraged to include in your user information the ORCID (\url{https://orcid.org/}) or register for one if you don't have it. This ID will help to identify you in the researcher community and make it easier to keep track of all your publications.
Please provide a valid ORCID here, e.g.,

\noindent Josiah Carberry - \url{https://orcid.org/0000-0002-1825-0097}

\noindent Rajesh Babu - \url{https://orcid.org/0009-0006-0415-6880}

\appendix

\section{Appendices}
Appendices should be used only when absolutely necessary. They should come before the References. If there is more than one appendix, number them alphabetically. Number displayed equations occurring in the Appendix in this way, e.g.~(\ref{appeqn}), (A.2), etc.
\begin{equation}
\mu(n, t) = {\sum^\infty_{i=1} 1(d_i < t, N(d_i) = n) \over
\int^t_{\sigma=0} 1(N(\sigma) = n)d\sigma}\,.
\label{appeqn}
\end{equation}

\section*{References}
References are to be listed in the order cited in the text in Arabic
numerals.  They can be typed in superscripts after punctuation marks,
e.g.~``$\ldots$ in the statement.\cite{1}'' or used directly,
e.g.~``see Ref.~5 for examples.'' Please list using the style shown in
the following examples.  For journal names, use the standard
abbreviations or spell in full.  Typeset references in 9 pt roman.

\begin{thebibliography}{0}

\bibitem{1} I. Haviv, On the binary and Boolean rank of regular matrices,
{\it J. Comput. System Sci.} {\bf 134} (2023) 73--86, \url{https://doi.org/10.1016/j.jcss.2023.01.005}.

\bibitem{2} R. Loren and D. B. Benson, Deterministic and nondeterministic flowchart interpretations, {\it J. Comput. System Sci.} {\bf 27}(3)
(1983) 400--433, \url{https://doi.org/10.1016/0022-0000(83)90050-8}.

\bibitem{3} C. M. Wang, J. N. Reddy and K. H. Lee, {\it Shear Deformable
Beams and Plates} (Elsevier, Oxford, 2000).
	
\bibitem{4} R. Loren and D. B. Benson (eds.), {\it Introduction to
String Field Theory}, 2nd edn. (Springer-Verlag, New York, 1999).

\bibitem{5} R. Loren, J. Li and D. B. Benson, Deterministic
flow-chart interpretations, in {\it Introduction to String Field Theory},
Advanced Series in Mathematical Physics, Vol.~3
(Springer-Verlag, New York, 1999), pp.~401--413.

\bibitem{6} R. Loren, J. Li and D. B. Benson, Deterministic flow-chart
interpretations, in {\it Proc. 3rd Int. Conf. Entity-Relationship
Approach}, eds.~C. G. Davis and R. T. Yeh (North-Holland, Amsterdam, 1983),
pp.~421--439.
\end{thebibliography}
\end{document}

\documentclass{ws-jams}

\usepackage{xcolor}
\usepackage[sort,super,compress]{cite}
\usepackage[verbose]{hyperref}
\hypersetup{colorlinks=false,allbordercolors=blue,pdfborderstyle={/S/U/W 1}}

\begin{document}

\def\bib{B\kern-.05em{I}\kern-.025em{B}\kern-.08em}
\def\btex{B\kern-.05em{I}\kern-.025em{B}\kern-.08em\TeX}

\title{\large B\kern-.05em{\large I}\kern-.025em{\large B}\kern-.08em\TeX ing\\[.5ex] in \\[.5ex] WSPC \bib\/
Style}

\markboth{WSPC}{Using World Scientific's \btex\/ Style File}

\maketitle

\section{Usage}

\begin{verbatim}
\documentclass{ws-jams}
\usepackage{cite}
\begin{document}
\section{Output}
Sample output using ws-jams bibliography style file ...
text\cite{best,pier,jame} ...
\bibliographystyle{ws-jams}
\bibliography{sample}
\end{document}
\end{verbatim}

\section{Output}
Sample output using ws-jams bibliography style file

\begin{enumerate}[(13)]
\item article: see \cite{best,pier,jame}

\item proceedings: see \cite{Weiss94}

\item inproceedings: see \cite{conftypical,Moss94}

\item book: see\cite{ArmsRace1}

\item edition: see \cite{ComplexVariables}

\item editor: see \cite{ColBenh:93}

\item series: see \cite{inbook}

\item tech report: see \cite{hobby1992,CSTR116}

\item unpublished: see \cite{VoQS}

\item PhD thesis: see \cite{Brown:1988:IEL}

\item Masters thesis: see \cite{segms}

\item incollection: see \cite{Jones:Phoneme}

\item booklet: see \cite{URW:kerning}
\end{enumerate}

\bibliographystyle{ws-jams}
\bibliography{sample}

\end{document}